[arch-commits] Commit in haskell-conduit-extra/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sun Dec 30 21:07:20 UTC 2018


    Date: Sunday, December 30, 2018 @ 21:07:19
  Author: felixonmars
Revision: 419759

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-conduit-extra/repos/community-staging-x86_64/
  haskell-conduit-extra/repos/community-staging-x86_64/PKGBUILD
    (from rev 419758, haskell-conduit-extra/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-conduit-extra/repos/community-staging-x86_64/PKGBUILD (from rev 419758, haskell-conduit-extra/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-12-30 21:07:19 UTC (rev 419759)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=conduit-extra
+pkgname=haskell-conduit-extra
+pkgver=1.3.0
+pkgrel=79
+pkgdesc="Batteries included conduit: adapters for common libraries."
+url="https://github.com/snoyberg/conduit"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-attoparsec' 'haskell-conduit' 'haskell-network'
+         'haskell-primitive' 'haskell-resourcet' 'haskell-streaming-commons' 'haskell-typed-process'
+         'haskell-unliftio-core')
+makedepends=('ghc' 'haskell-exceptions' 'haskell-hspec' 'haskell-quickcheck'
+             'haskell-transformers-base')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('3097a561b37b13e221f0721e84c06b179ec6df5111af7a2db12e26ee4f4d0935fb49bbccbda17e22546d11436774a5fa4b8df718c47f751bf5e846dfec92a7e5')
+
+prepare() {
+    sed -i '/bytestring-builder/d' $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


More information about the arch-commits mailing list