[arch-commits] Commit in python-greenlet/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Fri Feb 2 14:06:16 UTC 2018
Date: Friday, February 2, 2018 @ 14:06:15
Author: felixonmars
Revision: 288563
archrelease: copy trunk to community-testing-x86_64
Added:
python-greenlet/repos/community-testing-x86_64/
python-greenlet/repos/community-testing-x86_64/PKGBUILD
(from rev 288562, python-greenlet/trunk/PKGBUILD)
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Copied: python-greenlet/repos/community-testing-x86_64/PKGBUILD (from rev 288562, python-greenlet/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2018-02-02 14:06:15 UTC (rev 288563)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Ralf Schmitt <ralf at systemexit.de>
+
+pkgbase=python-greenlet
+pkgname=(python-greenlet python2-greenlet)
+pkgver=0.4.13
+pkgrel=1
+pkgdesc="Lightweight in-process concurrent programming"
+license=("MIT")
+arch=('x86_64')
+url="http://pypi.python.org/pypi/greenlet"
+makedepends=('python-setuptools' 'python2-setuptools')
+source=("https://files.pythonhosted.org/packages/source/g/greenlet/greenlet-${pkgver}.tar.gz")
+sha512sums=('625aaa8875b408442139191e1a63eca71c668675229907335f5caee623487aba5305c1d53b51e1764ad982b8edd07d04f984e08a75318a0a5672805667917a61')
+
+prepare() {
+ cp -a greenlet-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir"/greenlet-$pkgver
+ python setup.py build
+
+ cd "$srcdir"/greenlet-$pkgver-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/greenlet-$pkgver
+ python setup.py test
+
+ cd "$srcdir"/greenlet-$pkgver-py2
+ python2 setup.py test
+}
+
+package_python-greenlet() {
+ depends=('python')
+
+ cd greenlet-$pkgver
+ python setup.py install -O1 --root="$pkgdir"
+ install -Dm0644 LICENSE.PSF "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.PSF
+}
+
+package_python2-greenlet() {
+ depends=('python2')
+
+ cd greenlet-$pkgver-py2
+ python2 setup.py install -O1 --root="$pkgdir"
+ install -Dm0644 LICENSE.PSF "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.PSF
+}
More information about the arch-commits
mailing list