[arch-commits] Commit in gst-plugins-good/repos (2 files)

[Jan Steffens]

    Date: Saturday, February 3, 2018 @ 14:36:44
  Author: heftig
Revision: 315806

archrelease: copy trunk to staging-x86_64

Added:
  gst-plugins-good/repos/staging-x86_64/
  gst-plugins-good/repos/staging-x86_64/PKGBUILD
    (from rev 315805, gst-plugins-good/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: gst-plugins-good/repos/staging-x86_64/PKGBUILD (from rev 315805, gst-plugins-good/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-02-03 14:36:44 UTC (rev 315806)
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gst-plugins-good
+pkgver=1.12.4
+pkgrel=2
+pkgdesc="GStreamer Multimedia Framework Good Plugins"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(libpulse jack libsoup gst-plugins-base-libs wavpack aalib taglib libdv libshout libvpx
+         gdk-pixbuf2 libcaca libavc1394 libiec61883 libxdamage v4l-utils cairo libgudev speex flac
+         libraw1394)
+makedepends=(python gtk-doc autoconf-archive git)
+checkdepends=(gst-plugins-base)
+_commit=224938300a3b0fd8263422c3548576ac939032e5  # tags/1.12.4^0
+source=("git+https://anongit.freedesktop.org/git/gstreamer/gst-plugins-good#commit=$_commit"
+        "gst-common::git+https://anongit.freedesktop.org/git/gstreamer/common")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git config --local submodule.common.url "$srcdir/gst-common"
+  git submodule update
+
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
+    --with-package-name="GStreamer Good Plugins (Arch Linux)" \
+    --with-package-origin="https://www.archlinux.org/" \
+    --enable-experimental --enable-gtk-doc --disable-static
+
+  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}