[arch-commits] Commit in mc/repos (2 files)

[Bartłomiej Piotrowski]

    Date: Monday, February 5, 2018 @ 07:20:17
  Author: bpiotrowski
Revision: 289131

archrelease: copy trunk to community-testing-x86_64

Added:
  mc/repos/community-testing-x86_64/
  mc/repos/community-testing-x86_64/PKGBUILD
    (from rev 289130, mc/trunk/PKGBUILD)

----------+
 PKGBUILD |   61 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

Copied: mc/repos/community-testing-x86_64/PKGBUILD (from rev 289130, mc/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2018-02-05 07:20:17 UTC (rev 289131)
@@ -0,0 +1,61 @@
+# $Id$
+# Maintainer: schuay <jakob.gruber at gmail.com>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=mc
+pkgver=4.8.20
+pkgrel=2
+pkgdesc="Midnight Commander is a text based filemanager/shell that emulates Norton Commander"
+arch=('x86_64')
+url="http://www.ibiblio.org/mc/"
+license=('GPL')
+depends=('e2fsprogs' 'glib2' 'gpm' 'libssh2' 'ncurses')
+makedepends=('libxt' 'libx11' 'unzip')
+optdepends=('aspell: spelling corrections'
+            'cabextract: ucab extfs'
+            'cdparanoia: audio extfs'
+            'cdrkit: iso9660 extfs'
+            'cvs: CVS support'
+            'gawk: hp48+ extfs'
+            'mtools: a+ extfs'
+            'p7zip: support for 7zip archives'
+            'perl: needed by several extfs scripts'
+            'python2-boto: s3+ extfs'
+            'python2-pytz: s3+ extfs'
+            'samba: VFS support'
+            'unace: uace extfs'
+            'unarj: uarj extfs'
+            'unrar: urar extfs'
+            'zip: uzip extfs')
+backup=('etc/mc/edit.indent.rc'
+        'etc/mc/filehighlight.ini'
+        'etc/mc/mc.ext'
+        'etc/mc/mc.keymap'
+        'etc/mc/mc.menu'
+        'etc/mc/mcedit.menu'
+        'etc/mc/sfs.ini')
+options=('!emptydirs')
+source=("http://ftp.midnight-commander.org/${pkgname}-${pkgver}.tar.xz")
+sha256sums=('017ee7f4f8ae420a04f4d6fcebaabe5b494661075c75442c76e9c8b1923d501c')
+
+build() {
+  export PYTHON=/usr/bin/python2
+
+  cd ${pkgname}-${pkgver}
+  ./configure \
+      --prefix=/usr \
+      --libexecdir=/usr/lib \
+      --sysconfdir=/etc \
+      --enable-vfs-smb \
+      --with-screen=ncurses \
+      --with-x
+  make
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+
+  # Replace mc.keymap symlink with target file to fix backup mechanism (FS#50889).
+  rm "${pkgdir}"/etc/mc/mc.keymap && cp "${pkgdir}"/etc/mc/mc{.default,}.keymap
+}