[arch-commits] Commit in haskell-conduit-extra/repos (2 files)

[Felix Yan]

    Date: Tuesday, February 6, 2018 @ 20:25:05
  Author: felixonmars
Revision: 289527

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-conduit-extra/repos/community-staging-x86_64/
  haskell-conduit-extra/repos/community-staging-x86_64/PKGBUILD
    (from rev 289526, haskell-conduit-extra/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-conduit-extra/repos/community-staging-x86_64/PKGBUILD (from rev 289526, haskell-conduit-extra/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-02-06 20:25:05 UTC (rev 289527)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=conduit-extra
+pkgname=haskell-conduit-extra
+pkgver=1.2.3.2
+pkgrel=8
+pkgdesc="Batteries included conduit: adapters for common libraries."
+url="https://github.com/snoyberg/conduit"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-attoparsec' 'haskell-blaze-builder' 'haskell-conduit'
+         'haskell-exceptions' 'haskell-monad-control' 'haskell-network' 'haskell-primitive'
+         'haskell-resourcet' 'haskell-stm' 'haskell-streaming-commons' 'haskell-text'
+         'haskell-transformers-base' 'haskell-typed-process' 'haskell-unliftio-core')
+makedepends=('ghc' 'haskell-hspec' 'haskell-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('758fe17c11be7eb82fe761be33cce68614bb148cec36486bb4903eed818f6a79b495788223447ec5fdff112d71a45f3b347db5c41fe6266c52021c7987839112')
+
+prepare() {
+    sed -i '/bytestring-builder/d' $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}