[arch-commits] Commit in ardour/repos (3 files)

[David Runge]

    Date: Thursday, February 8, 2018 @ 18:09:32
  Author: dvzrv
Revision: 290321

archrelease: copy trunk to community-testing-x86_64

Added:
  ardour/repos/community-testing-x86_64/
  ardour/repos/community-testing-x86_64/.contrib
    (from rev 290320, ardour/trunk/.contrib)
  ardour/repos/community-testing-x86_64/PKGBUILD
    (from rev 290320, ardour/trunk/PKGBUILD)

----------+
 .contrib |    2 ++
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 52 insertions(+)

Copied: ardour/repos/community-testing-x86_64/.contrib (from rev 290320, ardour/trunk/.contrib)
===================================================================
--- community-testing-x86_64/.contrib	                        (rev 0)
+++ community-testing-x86_64/.contrib	2018-02-08 18:09:32 UTC (rev 290321)
@@ -0,0 +1,2 @@
+# Contributor: Bernardo Barros <bernardobarros at gmail.com>
+# Contributor: Uli Armbruster <uli_armbruster at web.de>

Copied: ardour/repos/community-testing-x86_64/PKGBUILD (from rev 290320, ardour/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2018-02-08 18:09:32 UTC (rev 290321)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: David Runge <dave at sleepmap.de>
+# Maintainer: Ray Rashif <schiv at archlinux.org>
+# Contributor: SpepS <dreamspepser at yahoo dot it>
+
+_name=Ardour
+pkgname=ardour
+pkgver=5.12
+pkgrel=3
+pkgdesc="Professional-grade digital audio workstation"
+arch=('x86_64')
+url="https://ardour.org/"
+license=('GPL')
+depends=('liblrdf' 'libarchive' 'liblo' 'lilv' 'suil' 'taglib' 'aubio'
+'rubberband' 'gtkmm')
+makedepends=('boost' 'cppunit' 'git' 'itstool' 'python2')
+optdepends=('xjadeo: video monitoring'
+            'harvid: video timeline')
+source=("${pkgname}-${pkgver}::git+https://github.com/${pkgname}/${pkgname}.git#tag=${pkgver}")
+sha512sums=('SKIP')
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  python2 waf configure --prefix=/usr \
+                       --configdir=/etc \
+                       --with-backends="jack,alsa,dummy" \
+                       --libjack=weak \
+                       --optimize \
+                       --cxx11 \
+                       --freedesktop \
+                       --ptformat \
+                       --no-phone-home
+  python2 waf build
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  python2 waf install --destdir="${pkgdir}"
+  # xdg integration
+  install -vDm644 "build/gtk2_${pkgname}/${pkgname}.xml" \
+    "${pkgdir}/usr/share/mime/application/x-${pkgname}.xml"
+  install -vDm644 "build/gtk2_${pkgname}/${pkgname}${pkgver%%.*}.desktop" \
+    "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+  for size in 16 22 32 48 256 512; do
+    install -vDm644 "gtk2_${pkgname}/resources/${_name}-icon_${size}px.png" \
+      "${pkgdir}/usr/share/icons/hicolor/${size}x${size}/apps/${pkgname}${pkgver%%.*}.png"
+  done
+}
+
+# vim:set ts=2 sw=2 et: