[arch-commits] Commit in haskell-network-protocol-xmpp/repos (2 files)

[Felix Yan]

    Date: Saturday, February 17, 2018 @ 07:51:05
  Author: felixonmars
Revision: 295843

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-network-protocol-xmpp/repos/community-staging-x86_64/
  haskell-network-protocol-xmpp/repos/community-staging-x86_64/PKGBUILD
    (from rev 295842, haskell-network-protocol-xmpp/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: haskell-network-protocol-xmpp/repos/community-staging-x86_64/PKGBUILD (from rev 295842, haskell-network-protocol-xmpp/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-02-17 07:51:05 UTC (rev 295843)
@@ -0,0 +1,39 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=network-protocol-xmpp
+pkgname=haskell-network-protocol-xmpp
+pkgver=0.4.8
+pkgrel=20
+pkgdesc="Client library for the XMPP protocol."
+url="https://john-millikin.com/software/haskell-xmpp/"
+license=("GPL3")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-gnuidn" "haskell-gnutls" "haskell-gsasl" "haskell-libxml-sax"
+         "haskell-monads-tf" "haskell-network" "haskell-text" "haskell-xml-types")
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('029cbb1a0ea6691fd886b326eee7a24e8300bbece1f0c0f564b43b0e344f4107ca980d97342271cab0b9c1333fc445ac10f7dfae41dd2b6e6ea995bfb810311e')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/license.txt"
+}