[arch-commits] Commit in (9 files)
Sergej Pupykin
spupykin at archlinux.org
Tue Feb 20 18:10:00 UTC 2018
Date: Tuesday, February 20, 2018 @ 18:09:51
Author: spupykin
Revision: 296535
add psi-l10n and psi-plugins packages
Added:
psi-l10n/
psi-l10n/repos/
psi-l10n/trunk/
psi-l10n/trunk/PKGBUILD
psi-plugins/
psi-plugins/repos/
psi-plugins/trunk/
psi-plugins/trunk/PKGBUILD
psi-plugins/trunk/psiplugin.pri
---------------------------------+
psi-l10n/trunk/PKGBUILD | 30 ++++++++++++++++++++++++
psi-plugins/trunk/PKGBUILD | 47 ++++++++++++++++++++++++++++++++++++++
psi-plugins/trunk/psiplugin.pri | 18 ++++++++++++++
3 files changed, 95 insertions(+)
Added: psi-l10n/trunk/PKGBUILD
===================================================================
--- psi-l10n/trunk/PKGBUILD (rev 0)
+++ psi-l10n/trunk/PKGBUILD 2018-02-20 18:09:51 UTC (rev 296535)
@@ -0,0 +1,30 @@
+# $Id: PKGBUILD 264278 2017-10-25 15:45:36Z spupykin $
+# Maintainer: Sergej Pupykin <arch+pub at sergej.pp.ru>
+
+pkgname=psi-l10n
+pkgver=1.3
+pkgrel=1
+pkgdesc="Language packs for Psi+ (Qt 5.x build)"
+arch=('any')
+url="http://psi-plus.com"
+license=('GPL2')
+depends=('psi')
+conflicts=('psi-l10n')
+replaces=('psi-l10n')
+makedepends=('qt5-tools' 'git')
+options=('!strip' '!zipman')
+source=("git://github.com/psi-plus/psi-plus-l10n.git#tag=$pkgver")
+sha256sums=('SKIP')
+
+build() {
+ cd psi-plus-l10n/translations
+ for langfile in *.ts; do
+ lrelease-qt5 "$langfile"
+ done
+}
+
+package() {
+ cd psi-plus-l10n/translations
+ install -v -dm755 "$pkgdir/usr/share/psi-plus/translations"
+ install -v -m644 *.qm "$pkgdir/usr/share/psi-plus/translations"
+}
Added: psi-plugins/trunk/PKGBUILD
===================================================================
--- psi-plugins/trunk/PKGBUILD (rev 0)
+++ psi-plugins/trunk/PKGBUILD 2018-02-20 18:09:51 UTC (rev 296535)
@@ -0,0 +1,47 @@
+# $Id: PKGBUILD 266875 2017-11-15 14:29:11Z foutrelis $
+# Maintainer: Sergej Pupykin <arch+pub at sergej.pp.ru>
+
+pkgname=psi-plugins
+pkgver=1.3
+pkgrel=1
+pkgdesc="Additional plugins for Psi+ (built with Qt 5.x)"
+arch=('x86_64')
+url="http://psi-plus.com"
+license=('GPL2')
+depends=('qt5-base' 'qt5-webkit' 'qt5-multimedia' 'psi' 'qt5-webengine')
+conflicts=('psi-plus-plugins-git' 'psi-plus-plugins-qt5-git' 'psi-plus-plugins')
+replaces=('psi-plus-plugins')
+makedepends=('libotr' 'tidyhtml' 'git')
+optdepends=('libotr: for OTR plugin'
+ 'tidyhtml: for OTR plugin')
+source=("psi-plus-plugins::git://github.com/psi-im/plugins.git#tag=$pkgver"
+ 'psiplugin.pri')
+sha256sums=('SKIP'
+ '2be7b26400faecf69d552b89ed8470cb461ba1c8c56e3e8646d166feb0de56c6')
+
+prepare() {
+ cp -v psiplugin.pri psi-plus-plugins/
+}
+
+build() {
+ cd psi-plus-plugins
+ # Kill broken plugins
+ rm -rf generic/juickplugin
+ for plugin in generic/*; do
+ if [ -d "$srcdir/psi-plus-plugins/$plugin" ]; then
+ cd "$srcdir/psi-plus-plugins/$plugin"
+ qmake-qt5 PREFIX="/usr" QMAKE_STRIP=
+ make
+ fi
+ done
+}
+
+package() {
+ cd psi-plus-plugins
+ for plugin in generic/* unix/*; do
+ if [ -d "$srcdir/psi-plus-plugins/$plugin" ]; then
+ cd "$srcdir/psi-plus-plugins/$plugin"
+ make INSTALL_ROOT="$pkgdir" install
+ fi
+ done
+}
Added: psi-plugins/trunk/psiplugin.pri
===================================================================
--- psi-plugins/trunk/psiplugin.pri (rev 0)
+++ psi-plugins/trunk/psiplugin.pri 2018-02-20 18:09:51 UTC (rev 296535)
@@ -0,0 +1,18 @@
+TEMPLATE = lib
+CONFIG += plugin
+QT += xml
+QT += widgets
+
+MOC_DIR = .moc/
+OBJECTS_DIR = .obj/
+RCC_DIR = .rcc/
+UI_DIR = .ui/
+
+INCLUDEPATH += .ui/
+
+target.path = /usr/lib/psi-plus/plugins
+INSTALLS += target
+
+INCLUDEPATH += /usr/include/psi-plus/plugins
+
+DEFINES += HAVE_QT5
\ No newline at end of file
More information about the arch-commits
mailing list