[arch-commits] Commit in libinput/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Jan de Groot
jgc at archlinux.org
Fri Feb 23 21:12:55 UTC 2018
Date: Friday, February 23, 2018 @ 21:12:53
Author: jgc
Revision: 317443
archrelease: copy trunk to testing-x86_64
Added:
libinput/repos/testing-x86_64/
libinput/repos/testing-x86_64/PKGBUILD
(from rev 317442, libinput/trunk/PKGBUILD)
----------+
PKGBUILD | 47 +++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 47 insertions(+)
Copied: libinput/repos/testing-x86_64/PKGBUILD (from rev 317442, libinput/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2018-02-23 21:12:53 UTC (rev 317443)
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Andreas Radke <andyrtr at archlinux.org>
+# Maintainer: Jan de Groot
+
+pkgname=libinput
+pkgver=1.10.0+25+g3e77f2e9
+pkgrel=1
+pkgdesc="Input device management and event handling library"
+url="https://www.freedesktop.org/wiki/Software/libinput/"
+arch=(x86_64)
+license=(custom:X11)
+depends=('mtdev' 'systemd' 'libevdev' 'libwacom')
+makedepends=('doxygen' 'graphviz' 'gtk3' 'meson' git)
+optdepends=('gtk3: libinput debug-gui'
+ 'python-pyudev: libinput measure'
+ 'python-evdev: libinput measure')
+_commit=3e77f2e9f5a98fc5917642bd47ceeef89b95c858 # master
+source=("git+https://anongit.freedesktop.org/git/wayland/libinput#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ # Reduce docs size
+ printf '%s\n' >>doc/libinput.doxygen.in \
+ HAVE_DOT=yes DOT_IMAGE_FORMAT=svg INTERACTIVE_SVG=yes
+}
+
+build() {
+ arch-meson $pkgname build -Dtests=false
+ ninja -C build
+}
+
+package() {
+ DESTDIR="$pkgdir" ninja -C build install
+
+ install -Dvm644 $pkgname/COPYING \
+ "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+ # install doc - no Makefile target
+ install -d "$pkgdir/usr/share/doc"
+ cp -av build/html "$pkgdir/usr/share/doc/libinput"
+}
More information about the arch-commits
mailing list