[arch-commits] Commit in wget/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Levente Polyak
anthraxx at archlinux.org
Mon Feb 26 00:21:13 UTC 2018
Date: Monday, February 26, 2018 @ 00:21:04
Author: anthraxx
Revision: 317531
archrelease: copy trunk to staging-x86_64
Added:
wget/repos/staging-x86_64/
wget/repos/staging-x86_64/PKGBUILD
(from rev 317530, wget/trunk/PKGBUILD)
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Copied: wget/repos/staging-x86_64/PKGBUILD (from rev 317530, wget/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2018-02-26 00:21:04 UTC (rev 317531)
@@ -0,0 +1,52 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Eric Bélanger <eric at archlinux.org>
+
+pkgname=wget
+pkgver=1.19.4
+pkgrel=2
+pkgdesc='Network utility to retrieve files from the Web'
+url='https://www.gnu.org/software/wget/wget.html'
+arch=('x86_64')
+license=('GPL3')
+depends=('glibc' 'gnutls' 'libidn' 'libutil-linux' 'libpsl' 'pcre')
+checkdepends=('perl-http-daemon' 'perl-io-socket-ssl' 'python')
+optdepends=('ca-certificates: HTTPS downloads')
+backup=('etc/wgetrc')
+source=(https://ftp.gnu.org/gnu/${pkgname}/${pkgname}-${pkgver}.tar.lz{,.sig})
+sha256sums=('2fc0ffb965a8dc8f1e4a89cbe834c0ae7b9c22f559ebafc84c7874ad1866559a'
+ 'SKIP')
+validpgpkeys=('AC404C1C0BF735C63FF4D562263D6DF2E163E1EA'
+ '7845120B07CBD8D6ECE5FF2B2A1743EDA91A35B6'
+ '1CB27DBC98614B2D5841646D08302DB6A2670428') # Tim Rühsen <tim.ruehsen at gmx.de>
+
+prepare() {
+ cd ${pkgname}-${pkgver}
+ cat >> doc/sample.wgetrc <<EOF
+
+# default root certs location
+ca_certificate=/etc/ssl/certs/ca-certificates.crt
+EOF
+}
+
+build() {
+ cd ${pkgname}-${pkgver}
+ ./configure \
+ --prefix=/usr \
+ --sysconfdir=/etc \
+ --disable-rpath \
+ --enable-nls \
+ --with-ssl=gnutls
+ make
+}
+
+check() {
+ cd ${pkgname}-${pkgver}
+ make check < /dev/null
+}
+
+package() {
+ cd ${pkgname}-${pkgver}
+ make DESTDIR="${pkgdir}" install
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list