[arch-commits] Commit in kio-extras/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Monday, February 26, 2018 @ 03:12:23
  Author: arojas
Revision: 317541

archrelease: copy trunk to staging-x86_64

Added:
  kio-extras/repos/staging-x86_64/
  kio-extras/repos/staging-x86_64/PKGBUILD
    (from rev 317540, kio-extras/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: kio-extras/repos/staging-x86_64/PKGBUILD (from rev 317540, kio-extras/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-02-26 03:12:23 UTC (rev 317541)
@@ -0,0 +1,43 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=kio-extras
+pkgver=17.12.2
+pkgrel=2
+pkgdesc="Additional components to increase the functionality of KIO"
+arch=(x86_64)
+url='https://www.kde.org/applications/internet/'
+license=(LGPL)
+depends=(kio kdnssd libssh smbclient exiv2 openexr libmtp kpty kactivities)
+makedepends=(extra-cmake-modules kdoctools qt5-webengine gperf taglib khtml)
+optdepends=('qt5-webengine: HTML thumbnailer' 'qt5-imageformats: thumbnails for additional image formats'
+            'kimageformats: thumbnails for additional image formats' 'taglib: audio file thumbnails'
+            'khtml: man kioslave')
+groups=(kde-applications kdenetwork)
+source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('d7dfe8b6306f0d7c2b47056306376244f5947e758938182c444463963ae7886d'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}
+