[arch-commits] Commit in urwidtrees/repos (community-any community-any/PKGBUILD)
Lukas Fleischer
lfleischer at archlinux.org
Mon Feb 26 09:47:24 UTC 2018
Date: Monday, February 26, 2018 @ 09:47:16
Author: lfleischer
Revision: 298261
archrelease: copy trunk to community-any
Added:
urwidtrees/repos/community-any/
urwidtrees/repos/community-any/PKGBUILD
(from rev 298260, urwidtrees/trunk/PKGBUILD)
----------+
PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
1 file changed, 42 insertions(+)
Copied: urwidtrees/repos/community-any/PKGBUILD (from rev 298260, urwidtrees/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD (rev 0)
+++ community-any/PKGBUILD 2018-02-26 09:47:16 UTC (rev 298261)
@@ -0,0 +1,42 @@
+# Maintainer: Lukas Fleischer <lfleischer at archlinux.org>
+# Contributor: Ian Denhardt <ian at zenhack.net>
+
+_pkgname=urwidtrees
+pkgbase=python-$_pkgname
+pkgname=(python-$_pkgname python2-$_pkgname)
+pkgver=1.0.2
+pkgrel=1
+pkgdesc="Tree widgets for urwid."
+arch=(any)
+url="https://github.com/pazz/$_pkgname"
+license=(GPL3)
+makedepends=(python 'python-urwid>=1.1.0' python-sphinx
+ python2 'python2-urwid>=1.1.0' python2-sphinx)
+source=("$_pkgname-$pkgver.tar.gz::https://github.com/pazz/$_pkgname/archive/$pkgver.tar.gz")
+md5sums=('07699e009203486f9c1e19c2fd5ef201')
+
+build() {
+ cd "$srcdir/$_pkgname-$pkgver"
+ python setup.py build
+ make SPHINXBUILD=sphinx-build -C docs man html
+}
+
+package_python-urwidtrees() {
+ depends=(python 'python-urwid>=1.1.0')
+ cd "$srcdir/$_pkgname-$pkgver"
+
+ python setup.py install --optimize=1 --root="$pkgdir"
+
+ install -dm755 "$pkgdir/usr/share/doc/$pkgname"
+ cp -a docs/build/html/* "$pkgdir/usr/share/doc/$pkgname"
+}
+
+package_python2-urwidtrees() {
+ depends=(python2 'python2-urwid>=1.1.0')
+ cd "$srcdir/$_pkgname-$pkgver"
+
+ python2 setup.py install --optimize=1 --root="$pkgdir"
+
+ install -dm755 "$pkgdir/usr/share/doc/$pkgname"
+ cp -a docs/build/html/* "$pkgdir/usr/share/doc/$pkgname"
+}
More information about the arch-commits
mailing list