[arch-commits] Commit in ruby-addressable/repos (2 files)

[Evangelos Foutras]

    Date: Wednesday, January 3, 2018 @ 08:03:58
  Author: foutrelis
Revision: 278013

archrelease: copy trunk to community-staging-any

Added:
  ruby-addressable/repos/community-staging-any/
  ruby-addressable/repos/community-staging-any/PKGBUILD
    (from rev 278012, ruby-addressable/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: ruby-addressable/repos/community-staging-any/PKGBUILD (from rev 278012, ruby-addressable/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2018-01-03 08:03:58 UTC (rev 278013)
@@ -0,0 +1,39 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Mario Finelli <mario at finel dot li>
+# Contributor: Artem Vorotnikov <artem at vorotnikov dot me>
+
+_gemname=addressable
+pkgname=ruby-addressable
+pkgver=2.5.2
+pkgrel=3
+pkgdesc='URI Implementation'
+arch=('any')
+url='https://github.com/sporkmonger/addressable'
+license=('Apache')
+depends=('ruby' 'ruby-public_suffix')
+options=('!emptydirs')
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/sporkmonger/addressable/archive/addressable-${pkgver}.tar.gz)
+sha256sums=('83538926352a01a6a340f4afad232766551c9048459704e2fc1a1e2b9d7f367b')
+sha512sums=('43052e4ec3a7f7439ac2a2d7c33511175f4219ee1b214173d502bc2643ac40646bd1a0f5bd77a0694fd0af32f20a52f89289cf3469edd376cde3db85f974e3f9')
+
+prepare() {
+  cd ${_gemname}-${_gemname}-${pkgver}
+  sed -r 's|~>|>=|g' -i ${_gemname}.gemspec # don't give a fuck about rubys bla bla
+}
+
+build() {
+  cd ${_gemname}-${_gemname}-${pkgver}
+  gem build ${_gemname}.gemspec
+}
+
+package() {
+  cd ${_gemname}-${_gemname}-${pkgver}
+  local _gemdir="$(gem env gemdir)"
+  gem install --ignore-dependencies --no-user-install -i "${pkgdir}${_gemdir}" -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
+  install -Dm 644 README.md CHANGELOG.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  rm "${pkgdir}/${_gemdir}/cache/${_gemname}-${pkgver}.gem"
+}
+
+# vim: ts=2 sw=2 et: