[arch-commits] Commit in ruby2.4/repos (2 files)
Anatol Pomozov
anatolik at archlinux.org
Thu Jan 4 00:07:57 UTC 2018
Date: Thursday, January 4, 2018 @ 00:07:56
Author: anatolik
Revision: 278372
archrelease: copy trunk to community-staging-x86_64
Added:
ruby2.4/repos/community-staging-x86_64/
ruby2.4/repos/community-staging-x86_64/PKGBUILD
(from rev 278371, ruby2.4/trunk/PKGBUILD)
----------+
PKGBUILD | 64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 64 insertions(+)
Copied: ruby2.4/repos/community-staging-x86_64/PKGBUILD (from rev 278371, ruby2.4/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2018-01-04 00:07:56 UTC (rev 278372)
@@ -0,0 +1,64 @@
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+# Contributor: Sergey Shatunov <me at prok.pw>
+# Contributor: Jonne Haß <me at jhass.eu>
+# Contributor: Thomas Dziedzic <gostrc at gmail.com>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: John Proctor <jproctor at prium.net>
+# Contributor: Jeramy Rutley <jrutley at gmail.com>
+
+_rubyver=2.4
+pkgname=ruby2.4
+pkgver=${_rubyver}.3
+pkgdesc='An object-oriented language for quick and easy programming'
+pkgrel=1
+arch=(x86_64)
+url='http://www.ruby-lang.org/en/'
+license=(BSD custom)
+depends=(gdbm openssl libffi libyaml gmp zlib)
+optdepends=('tk: for Ruby/TK')
+makedepends=(doxygen graphviz ttf-dejavu tk)
+options=(!emptydirs)
+source=(https://cache.ruby-lang.org/pub/ruby/${pkgver:0:3}/ruby-${pkgver}.tar.xz)
+sha512sums=('8bcf60c994a96787da5d743c66f5609a5a6d834d6d61243cdea7fd059197c3b10da43c99e5649be85e2f2329eedcbb1dd76e89ce3ac586be9056348f7449ed09')
+
+build() {
+ cd ruby-${pkgver}
+
+ PKG_CONFIG=/usr/bin/pkg-config ./configure \
+ --prefix=/opt/ruby${_rubyver} \
+ --program-suffix=-${_rubyver} \
+ --sysconfdir=/etc \
+ --localstatedir=/var \
+ --sharedstatedir=/var/lib \
+ --libexecdir=/usr/lib/ruby \
+ --enable-shared \
+ --disable-rpath \
+ --with-dbm-type=gdbm_compat
+
+ make ruby
+}
+
+check() {
+ cd ruby-${pkgver}
+
+ make test
+}
+
+package() {
+ cd ruby-${pkgver}
+
+ make DESTDIR="${pkgdir}" install-nodoc
+
+ install -dm755 $pkgdir/usr/bin
+ install -dm755 $pkgdir/usr/lib
+
+ for i in erb irb rdoc ri ruby testrb rake gem; do
+ ln -s /opt/$pkgname/bin/$i-${_rubyver} $pkgdir/usr/bin/$i-${_rubyver}
+ ln -s /opt/$pkgname/bin/$i-${_rubyver} $pkgdir/opt/$pkgname/bin/$i
+ done
+
+ ln -s /opt/$pkgname/lib/libruby.so.${_rubyver} $pkgdir/usr/lib/libruby.so.${_rubyver}
+
+ install -D -m644 COPYING "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
+ install -D -m644 BSDL "${pkgdir}/usr/share/licenses/$pkgname/BSDL"
+}
More information about the arch-commits
mailing list