[arch-commits] Commit in (4 files)
Bartłomiej Piotrowski
bpiotrowski at archlinux.org
Thu Jan 4 09:37:39 UTC 2018
Date: Thursday, January 4, 2018 @ 09:37:38
Author: bpiotrowski
Revision: 278595
extra2community: Moving libgovirt from extra to community
Added:
libgovirt/
libgovirt/repos/
libgovirt/trunk/
libgovirt/trunk/PKGBUILD
----------+
PKGBUILD | 42 ++++++++++++++++++++++++++++++++++++++++++
1 file changed, 42 insertions(+)
Added: libgovirt/trunk/PKGBUILD
===================================================================
--- libgovirt/trunk/PKGBUILD (rev 0)
+++ libgovirt/trunk/PKGBUILD 2018-01-04 09:37:38 UTC (rev 278595)
@@ -0,0 +1,42 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=libgovirt
+pkgver=0.3.4+45+g46288e8
+pkgrel=1
+pkgdesc="GObject-based library to access oVirt REST API"
+arch=(x86_64)
+url="https://git.gnome.org/browse/libgovirt"
+license=(GPL)
+depends=(glib2 rest)
+makedepends=(gobject-introspection git)
+_commit=46288e859023c6a1b3450d29456e59c999a69799 # master
+source=("git+https://git.gnome.org/browse/libgovirt#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed -e 's/^v//' -e 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ autoreconf -fvi
+}
+
+build(){
+ cd $pkgname
+ ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+ make
+}
+
+check(){
+ cd $pkgname
+ make check
+}
+
+package(){
+ cd $pkgname
+ make DESTDIR="${pkgdir}" install
+}
Property changes on: libgovirt/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
More information about the arch-commits
mailing list