[arch-commits] Commit in haskell-persistent/repos (2 files)

[Felix Yan]

    Date: Friday, January 5, 2018 @ 05:24:08
  Author: felixonmars
Revision: 278849

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-persistent/repos/community-staging-x86_64/
  haskell-persistent/repos/community-staging-x86_64/PKGBUILD
    (from rev 278848, haskell-persistent/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-persistent/repos/community-staging-x86_64/PKGBUILD (from rev 278848, haskell-persistent/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-01-05 05:24:08 UTC (rev 278849)
@@ -0,0 +1,51 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=persistent
+pkgname=haskell-persistent
+pkgver=2.7.3
+pkgrel=7
+pkgdesc="Type-safe, multi-backend data serialization"
+url="http://www.yesodweb.com/book/persistent"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-base64-bytestring'
+         'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-conduit' 'haskell-exceptions'
+         'haskell-fast-logger' 'haskell-http-api-data' 'haskell-lifted-base'
+         'haskell-monad-control' 'haskell-monad-logger' 'haskell-mtl' 'haskell-old-locale'
+         'haskell-path-pieces' 'haskell-resource-pool' 'haskell-resourcet' 'haskell-scientific'
+         'haskell-silently' 'haskell-src-meta' 'haskell-tagged' 'haskell-text'
+         'haskell-transformers-base' 'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc' 'haskell-hspec')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('681cdbd86eeb8fbe1bbe1648c8ff3dce961350e6cc379ef4d47ed0cf85ceabf91e1893f12e3bb637a30aeeff127c057d11a61b1f3ace61e86df21db0416953e9')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-nooverlap
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}