[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Saturday, January 6, 2018 @ 08:04:24
  Author: felixonmars
Revision: 279380

addpkg: haskell-yesod-test 1.5.9.1-1

Added:
  haskell-yesod-test/
  haskell-yesod-test/repos/
  haskell-yesod-test/trunk/
  haskell-yesod-test/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: haskell-yesod-test/trunk/PKGBUILD
===================================================================
--- haskell-yesod-test/trunk/PKGBUILD	                        (rev 0)
+++ haskell-yesod-test/trunk/PKGBUILD	2018-01-06 08:04:24 UTC (rev 279380)
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=yesod-test
+pkgname=haskell-yesod-test
+pkgver=1.5.9.1
+pkgrel=1
+pkgdesc="Integration testing for WAI/Yesod Applications"
+url="http://www.yesodweb.com"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-hunit' 'haskell-attoparsec' 'haskell-blaze-builder'
+         'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-case-insensitive' 'haskell-cookie'
+         'haskell-hspec-core' 'haskell-html-conduit' 'haskell-http-types' 'haskell-monad-control'
+         'haskell-network' 'haskell-persistent' 'haskell-pretty-show' 'haskell-text' 'haskell-wai'
+         'haskell-wai-extra' 'haskell-xml-conduit' 'haskell-xml-types' 'haskell-yesod-core')
+makedepends=('ghc' 'haskell-yesod-form' 'haskell-lifted-base' 'haskell-hspec')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('9b33af1df7cdc526e4be9339f2ff84f1b2f748d5516f1a851fcd537df2500961a3ac07c74db6311d499cb233ddb802e425efc16f10c1dedb16239fac8b767bed')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}


Property changes on: haskell-yesod-test/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property