[arch-commits] Commit in librsvg/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Jan Steffens
heftig at archlinux.org
Tue Jan 9 03:11:27 UTC 2018
Date: Tuesday, January 9, 2018 @ 03:11:26
Author: heftig
Revision: 314278
archrelease: copy trunk to testing-x86_64
Added:
librsvg/repos/testing-x86_64/
librsvg/repos/testing-x86_64/PKGBUILD
(from rev 314277, librsvg/trunk/PKGBUILD)
----------+
PKGBUILD | 45 +++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 45 insertions(+)
Copied: librsvg/repos/testing-x86_64/PKGBUILD (from rev 314277, librsvg/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2018-01-09 03:11:26 UTC (rev 314278)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=librsvg
+pkgver=2.42.0
+pkgrel=1
+epoch=2
+pkgdesc="SVG rendering library"
+url="https://wiki.gnome.org/Projects/LibRsvg"
+arch=(x86_64)
+license=(LGPL)
+depends=(gdk-pixbuf2 pango libcroco)
+makedepends=(intltool gobject-introspection vala python2 gtk-doc git rust)
+_commit=2465e1bfc0aab8d03fb4a2c3a6b6cc110fcbde98 # tags/2.42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/librsvg.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgname
+ ./configure --prefix=/usr --disable-static --enable-vala --enable-gtk-doc
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' libtool
+ make
+}
+
+check() {
+ cd $pkgname
+ # Reftests fail due to differences in text rendering
+ # Even with the fixated font on master there are still differences on i686
+ make check || :
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list