[arch-commits] Commit in hledger-web/repos (2 files)

Felix Yan felixonmars at archlinux.org
Wed Jan 10 05:30:38 UTC 2018


    Date: Wednesday, January 10, 2018 @ 05:30:37
  Author: felixonmars
Revision: 280881

archrelease: copy trunk to community-staging-x86_64

Added:
  hledger-web/repos/community-staging-x86_64/
  hledger-web/repos/community-staging-x86_64/PKGBUILD
    (from rev 280880, hledger-web/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: hledger-web/repos/community-staging-x86_64/PKGBUILD (from rev 280880, hledger-web/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-01-10 05:30:37 UTC (rev 280881)
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hledger-web
+pkgver=1.5
+pkgrel=7
+pkgdesc="Web interface for the hledger accounting tool"
+url="http://hledger.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'hledger' 'haskell-hledger-lib' 'haskell-base-compat' 'haskell-blaze-html'
+         'haskell-blaze-markup' 'haskell-clientsession' 'haskell-cmdargs' 'haskell-data-default'
+         'haskell-hjsmin' 'haskell-http-conduit' 'haskell-http-client' 'haskell-hunit'
+         'haskell-conduit-extra' 'haskell-safe' 'haskell-shakespeare' 'haskell-text' 'haskell-wai'
+         'haskell-wai-extra' 'haskell-wai-handler-launch' 'haskell-warp' 'haskell-yesod'
+         'haskell-yesod-core' 'haskell-yesod-form' 'haskell-yesod-static' 'haskell-json'
+         'haskell-megaparsec' 'haskell-mtl' 'haskell-parsec')
+makedepends=('ghc' 'haskell-hspec' 'haskell-yesod-test')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('3ba0b9e7d03a9d813e41f7f36ca0fa34decf6f04163abea850cb5ff6e322387b60952bfb30f46be817f52b2c79641fba03e62a5d6483b78a7e094c91fbb273a6')
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-dev -f-library-only -fthreaded
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}



More information about the arch-commits mailing list