[arch-commits] Commit in (3 files)

[Eli Schwartz]

    Date: Thursday, January 11, 2018 @ 07:43:34
  Author: eschwartz
Revision: 281289

Add firefox-extension-https-everywhere from the AUR.

Bump to the latest release.

Added:
  firefox-extension-https-everywhere/
  firefox-extension-https-everywhere/trunk/
  firefox-extension-https-everywhere/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: firefox-extension-https-everywhere/trunk/PKGBUILD
===================================================================
--- firefox-extension-https-everywhere/trunk/PKGBUILD	                        (rev 0)
+++ firefox-extension-https-everywhere/trunk/PKGBUILD	2018-01-11 07:43:34 UTC (rev 281289)
@@ -0,0 +1,45 @@
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+# Contributor: Hyacinthe Cartiaux <hyacinthe.cartiaux at free.fr>
+
+_pkgname=https-everywhere
+pkgname=firefox-extension-${_pkgname}
+pkgver=2017.12.6
+pkgrel=1
+pkgdesc="Plugin for firefox which ensures you are using https whenever it's possible."
+arch=('any')
+url="https://www.eff.org/https-everywhere"
+license=('GPL2')
+groups=('firefox-addons')
+depends=("firefox")
+makedepends=("unzip")
+source=("${_pkgname}-${pkgver}.xpi::https://www.eff.org/files/https-everywhere-${pkgver}-eff.xpi"
+        "${_pkgname}-${pkgver}.xpi.sig::https://www.eff.org/files/https-everywhere-${pkgver}-eff.xpi.sig")
+noextract=("${_pkgname}-${pkgver}.xpi")
+sha256sums=('006cba154d6559cd388d8b88330182e98f8c0e18f94d39d061a68e0e6123abca'
+            'SKIP')
+validpgpkeys=('1073E74EB38BD6D19476CBF8EA9DBF9FB761A677') # William Budington <bill at eff.org>
+
+prepare() {
+  cd "$srcdir"
+
+  unzip -qqo "${_pkgname}-${pkgver}.xpi" -d "${_pkgname}-${pkgver}"
+}
+
+package() {
+  cd "${srcdir}"
+
+  if [[ -f ${_pkgname}-${pkgver}/install.rdf ]]; then
+    _extension_id="$(sed -n '/.*<em:id>\(.*\)<\/em:id>.*/{s//\1/p;q}' ${_pkgname}-${pkgver}/install.rdf)"
+  else
+    _extension_id="$(sed -n 's/.*"id": "\(.*\)".*/\1/p' ${_pkgname}-${pkgver}/manifest.json)"
+  fi
+  _extension_dest="${pkgdir}/usr/lib/firefox/browser/extensions/${_extension_id}"
+  # Should this extension be unpacked or not?
+  if grep -q '<em:unpack>true</em:unpack>' ${_pkgname}-${pkgver}/install.rdf 2>/dev/null; then
+    install -dm755 "${_extension_dest}"
+    cp -R ${_pkgname}-${pkgver}/* "${_extension_dest}"
+    chmod -R ugo+rX "${_extension_dest}"
+  else
+    install -Dm644 ${_pkgname}-${pkgver}.xpi "${_extension_dest}.xpi"
+  fi
+}