[arch-commits] Commit in audacious-plugins/repos (2 files)

[Evangelos Foutras]

    Date: Friday, January 12, 2018 @ 07:03:47
  Author: foutrelis
Revision: 314626

archrelease: copy trunk to staging-x86_64

Added:
  audacious-plugins/repos/staging-x86_64/
  audacious-plugins/repos/staging-x86_64/PKGBUILD
    (from rev 314625, audacious-plugins/trunk/PKGBUILD)

----------+
 PKGBUILD |   71 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 71 insertions(+)

Copied: audacious-plugins/repos/staging-x86_64/PKGBUILD (from rev 314625, audacious-plugins/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-01-12 07:03:47 UTC (rev 314626)
@@ -0,0 +1,71 @@
+# $Id$
+# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
+# Contributor: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+# Contributor: William Rea <sillywilly at gmail.com>
+
+pkgname=audacious-plugins
+pkgver=3.9
+pkgrel=2
+pkgdesc="Plugins for Audacious"
+arch=('x86_64')
+url="http://audacious-media-player.org/"
+license=('BSD' 'GPL')
+
+makedepends=("audacious>=$pkgver"
+             'glib2' 'python' # for gdbus-codegen
+             'alsa-lib' 'pulseaudio' 'jack2' 'lame' 'libvorbis' 'flac'
+             'mpg123' 'faad2' 'ffmpeg' 'libmodplug' 'fluidsynth' 'libcdio-paranoia' 'libsidplayfp' 'wavpack'
+             'dbus-glib' 'libsamplerate' 'libnotify' 'lirc' 'curl' 'libmtp'
+             'neon' 'libmms' 'libcue')
+
+optdepends=('alsa-lib: Advanced Linux Sound Arch. output'
+            'pulseaudio: PulseAudio output'
+            'jack2: Jack Audio Connection Kit output'
+            'lame: FileWriter MP3 output'
+            'libvorbis: Vorbis input, FileWriter Vorbis output'
+            'flac: FLAC input, FileWriter FLAC output'
+
+            'mpg123: MP3 input'
+            'faad2: AAC input'
+            'ffmpeg: ffaudio input'
+            'libmodplug: modplug input'
+            'fluidsynth: MIDI FluidSynth backend input'
+            'libcdio-paranoia: CD Digital Audio input'
+            'libsidplayfp: Commodore 64 audio input'
+            'wavpack: WavPack input'
+
+            'dbus-glib: Gnome Shortcuts Plugin'
+            'libsamplerate: Speed and Pitch Plugin'
+            'libnotify: libnotify OSD'
+            'lirc: LIRC'
+            'curl: AudioScrobbler Client'
+            'libmtp: Upload to MTP device'
+
+            'neon: neon-based http transport'
+            'libmms: libmms-based mms transport'
+            'libcue: CUE playlist format')
+
+source=(http://distfiles.audacious-media-player.org/$pkgname-$pkgver.tar.bz2)
+sha256sums=('8bf7f21089cb3406968cc9c71307774aee7100ec4607f28f63cf5690d5c927b8')
+
+prepare() {
+  cd "$srcdir/$pkgname-$pkgver"
+}
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  ./configure \
+    --prefix=/usr \
+    --enable-amidiplug
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et: