[arch-commits] Commit in gst-plugins-ugly/repos (2 files)
Jan Steffens
heftig at archlinux.org
Fri Jan 12 22:15:50 UTC 2018
Date: Friday, January 12, 2018 @ 22:15:49
Author: heftig
Revision: 314651
archrelease: copy trunk to staging-x86_64
Added:
gst-plugins-ugly/repos/staging-x86_64/
gst-plugins-ugly/repos/staging-x86_64/PKGBUILD
(from rev 314650, gst-plugins-ugly/trunk/PKGBUILD)
----------+
PKGBUILD | 59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 59 insertions(+)
Copied: gst-plugins-ugly/repos/staging-x86_64/PKGBUILD (from rev 314650, gst-plugins-ugly/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2018-01-12 22:15:49 UTC (rev 314651)
@@ -0,0 +1,59 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gst-plugins-ugly
+pkgver=1.12.4
+pkgrel=3
+pkgdesc="GStreamer Multimedia Framework Ugly Plugins"
+url="https://gstreamer.freedesktop.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gst-plugins-base-libs libdvdread lame libmpeg2 a52dec libsidplay
+ libcdio libx264 libx264-all opencore-amr mpg123)
+makedepends=(python gtk-doc x264 autoconf-archive git valgrind)
+_commit=46fab99f2ef5581d63c2d11c57fb741553ede37f # tags/1.12.4^0
+source=("git+https://anongit.freedesktop.org/git/gstreamer/gst-plugins-ugly#commit=$_commit"
+ "gst-common::git+https://anongit.freedesktop.org/git/gstreamer/common")
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+
+ git submodule init
+ git config --local submodule.common.url "$srcdir/gst-common"
+ git submodule update
+
+ NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+ cd $pkgname
+
+ ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
+ --with-package-name="GStreamer Ugly Plugins (Arch Linux)" \
+ --with-package-origin="https://www.archlinux.org/" \
+ --with-x264-libraries="/usr/lib/x264/libx264-8bit.so:/usr/lib/x264/libx264-10bit.so" \
+ --enable-experimental --enable-gtk-doc --disable-static
+
+ # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+ sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+ make
+}
+
+check() {
+ cd $pkgname
+ make check
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+}
More information about the arch-commits
mailing list