[arch-commits] Commit in libsrtp/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Jan Steffens
heftig at archlinux.org
Fri Jan 12 23:32:04 UTC 2018
Date: Friday, January 12, 2018 @ 23:32:02
Author: heftig
Revision: 314670
archrelease: copy trunk to staging-x86_64
Added:
libsrtp/repos/staging-x86_64/
libsrtp/repos/staging-x86_64/PKGBUILD
(from rev 314669, libsrtp/trunk/PKGBUILD)
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Copied: libsrtp/repos/staging-x86_64/PKGBUILD (from rev 314669, libsrtp/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2018-01-12 23:32:02 UTC (rev 314670)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Yejun Yang <yejunx AT gmail DOT com>
+# Contributor: Michal Krenek <mikos at sg1.cz>
+
+pkgname=libsrtp
+pkgver=2.1.0
+pkgrel=1
+epoch=1
+pkgdesc="Library for SRTP (Secure Realtime Transport Protocol)"
+url="https://github.com/cisco/libsrtp"
+arch=(x86_64)
+license=(BSD)
+depends=(openssl)
+makedepends=(git)
+checkdepends=(libpcap procps-ng)
+options=(staticlibs)
+_commit=93aba3e767502343c255fad8962dbf0ff29c4ca6 # tags/v2.1.0
+source=("git+https://github.com/cisco/libsrtp#commit=$_commit")
+sha256sums=('SKIP')
+
+# Broken: There are tags like v1.5.4 but also "moving" tags like v1 and v1.5
+#pkgver() {
+# cd $pkgname
+# git describe --tags | sed 's/^v//;s/-/+/g'
+#}
+
+prepare() {
+ cd $pkgname
+ autoreconf -fvi
+}
+
+build() {
+ cd $pkgname
+ ./configure --prefix=/usr --enable-openssl
+ make all
+ make shared_library # Keep separate to link test apps against static lib
+}
+
+check() {
+ cd $pkgname
+ make runtest
+}
+
+package() {
+ cd $pkgname
+ make DESTDIR="$pkgdir" install
+ install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 LICENSE
+}
More information about the arch-commits
mailing list