[arch-commits] Commit in python-cffi/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Felix Yan]

    Date: Saturday, January 13, 2018 @ 02:14:33
  Author: felixonmars
Revision: 314676

archrelease: copy trunk to testing-x86_64

Added:
  python-cffi/repos/testing-x86_64/
  python-cffi/repos/testing-x86_64/PKGBUILD
    (from rev 314675, python-cffi/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: python-cffi/repos/testing-x86_64/PKGBUILD (from rev 314675, python-cffi/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2018-01-13 02:14:33 UTC (rev 314676)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: lilydjwg <lilydjwg at gmail.com>
+
+pkgbase=python-cffi
+pkgname=(python-cffi python2-cffi)
+pkgver=1.11.3
+pkgrel=1
+pkgdesc="Foreign Function Interface for Python calling C code"
+arch=('x86_64')
+url="http://cffi.readthedocs.org/"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-pycparser' 'python2-pycparser')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("$pkgbase-$pkgver.tar.gz::https://bitbucket.org/cffi/cffi/get/v$pkgver.tar.gz")
+sha512sums=('91507072b6ab55e51c995cc652770b467946e43d7be2fffb1566aa9c7398ee5fbe95051b7aaba219045301a56b72e81b706eac87068705f4cbc741cba3aacba1')
+
+prepare() {
+  mv cffi-cffi-* cffi-$pkgver
+  cp -a cffi-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/cffi-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/cffi-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/cffi-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/cffi-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-cffi() {
+  depends=('python-pycparser')
+
+  cd cffi-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-cffi() {
+  depends=('python2-pycparser')
+
+  cd cffi-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}