[arch-commits] Commit in (ospray ospray/repos ospray/trunk ospray/trunk/PKGBUILD)

[Bruno Pagani]

    Date: Monday, January 15, 2018 @ 12:56:11
  Author: archange
Revision: 282640

Initial addition of ospray to [community]

Added:
  ospray/
  ospray/repos/
  ospray/trunk/
  ospray/trunk/PKGBUILD

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Added: ospray/trunk/PKGBUILD
===================================================================
--- ospray/trunk/PKGBUILD	                        (rev 0)
+++ ospray/trunk/PKGBUILD	2018-01-15 12:56:11 UTC (rev 282640)
@@ -0,0 +1,41 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=ospray
+pkgver=1.4.3
+pkgrel=1
+pkgdesc="A Ray Tracing Based Rendering Engine for High-Fidelity Visualization"
+arch=('x86_64')
+url="http://www.ospray.org/"
+license=('Apache')
+depends=('intel-tbb' 'embree' 'ispc' 'libgl' 'glfw-x11' 'glu' 'openmpi')
+makedepends=('cmake')
+source=(${pkgname}-${pkgver}.tar.gz::"https://github.com/ospray/OSPRay/archive/v${pkgver}.tar.gz")
+sha256sums=('f1844664a0785ca1c70d8a2d5224ec823ccbb18a14246d8b7da1df38d14e9928')
+
+prepare() {
+    mkdir -p build
+}
+
+build() {
+    cd build
+    cmake ../${pkgname}-${pkgver} \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=lib \
+        -DOSPRAY_BUILD_ISA=ALL \
+        -DOSPRAY_ENABLE_TESTING=ON \
+        -DOSPRAY_MODULE_BILINEAR_PATCH=ON \
+        -DOSPRAY_MODULE_MPI=ON
+    make
+}
+
+check() {
+    cd build
+    make test
+}
+
+package() {
+    cd build
+    make DESTDIR="${pkgdir}" install
+    # Remove tests
+    rm -f "${pkgdir}"/usr/bin/test_*
+}