[arch-commits] Commit in haskell-postgresql-binary/repos (2 files)

[Felix Yan]

    Date: Monday, January 15, 2018 @ 18:06:17
  Author: felixonmars
Revision: 282826

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-postgresql-binary/repos/community-staging-x86_64/
  haskell-postgresql-binary/repos/community-staging-x86_64/PKGBUILD
    (from rev 282825, haskell-postgresql-binary/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: haskell-postgresql-binary/repos/community-staging-x86_64/PKGBUILD (from rev 282825, haskell-postgresql-binary/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-01-15 18:06:17 UTC (rev 282826)
@@ -0,0 +1,42 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=postgresql-binary
+pkgname=haskell-postgresql-binary
+pkgver=0.12.1
+pkgrel=41
+pkgdesc="Encoders and decoders for the PostgreSQL's binary format"
+url="https://github.com/nikita-volkov/postgresql-binary"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' "haskell-aeson" "haskell-base-prelude" "haskell-binary-parser"
+         "haskell-bytestring-strict-builder" "haskell-loch-th" "haskell-network-ip"
+         "haskell-placeholders" "haskell-scientific" "haskell-text" "haskell-unordered-containers"
+         "haskell-uuid" "haskell-vector")
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('b4af6c71593f130da0ff6c462682fb570a4bd8108809eeb7a8cca45e2e340fd815dd3a94d72293a60f2072ed16f68bcb25a33009e742eca1383b934c4700f306')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}