[arch-commits] Commit in oxygen/repos (2 files)

Antonio Rojas arojas at archlinux.org
Mon Jan 15 19:54:43 UTC 2018


    Date: Monday, January 15, 2018 @ 19:54:42
  Author: arojas
Revision: 314820

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  oxygen/repos/kde-unstable-x86_64/
  oxygen/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 314819, oxygen/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

Copied: oxygen/repos/kde-unstable-x86_64/PKGBUILD (from rev 314819, oxygen/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2018-01-15 19:54:42 UTC (rev 314820)
@@ -0,0 +1,66 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgbase=oxygen
+pkgname=(oxygen oxygen-kde4)
+pkgver=5.11.95
+pkgrel=1
+arch=(x86_64)
+url='https://www.kde.org/workspaces/plasmadesktop/'
+license=(LGPL)
+makedepends=(frameworkintegration kcmutils kdecoration extra-cmake-modules kdoctools kdelibs automoc4 python)
+source=("https://download.kde.org/unstable/plasma/$pkgver/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('b9e0e862b9b4a84d37b23b86b64116c1e2262e6f49dec71d68776eff8cea4035'
+            'SKIP')
+validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell
+              '348C8651206633FD983A8FC4DEACEA00075E1D76'  # KDE Neon
+              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson
+              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart at gmail.com>
+
+prepare() {
+  mkdir -p build{,-kde4}
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DBUILD_TESTING=OFF
+  make
+  cd ..
+
+  cd build-kde4
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_TESTING=OFF \
+    -DUSE_KDE4=ON
+  make
+}
+
+package_oxygen() {
+  pkgdesc='KDE Oxygen style'
+  depends=(frameworkintegration kdecoration kcmutils kwayland hicolor-icon-theme)
+  conflicts=(oxygen-cursors)
+  replaces=(oxygen-cursors)
+  groups=(plasma)
+
+  cd build
+  make DESTDIR="$pkgdir" install
+}
+
+package_oxygen-kde4() {
+  pkgdesc='KDE Oxygen style for KDE4 applications'
+  depends=(kdelibs)
+
+  cd build-kde4
+  make DESTDIR="$pkgdir" install
+
+  # needed so that pure Qt4 apps are correctly themed
+  install -d -m755 "$pkgdir"/usr/lib/qt4/plugins/styles
+  ln -s /usr/lib/kde4/plugins/styles/oxygen.so "$pkgdir"/usr/lib/qt4/plugins/styles
+}



More information about the arch-commits mailing list