[arch-commits] Commit in php71-apcu (trunk trunk/PKGBUILD trunk/apcu.ini)

[Sergej Pupykin]

    Date: Tuesday, January 16, 2018 @ 08:33:10
  Author: spupykin
Revision: 283080

upgpkg: php71-apcu 5.1.8-2

Added:
  php71-apcu/trunk/
  php71-apcu/trunk/PKGBUILD
  php71-apcu/trunk/apcu.ini

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 apcu.ini |    3 +++
 2 files changed, 48 insertions(+)

Added: trunk/PKGBUILD
===================================================================
--- trunk/PKGBUILD	                        (rev 0)
+++ trunk/PKGBUILD	2018-01-16 08:33:10 UTC (rev 283080)
@@ -0,0 +1,45 @@
+# $Id$
+
+pkgname=php71-apcu
+pkgver=5.1.8
+pkgrel=2
+arch=('x86_64')
+pkgdesc='A userland caching module for PHP'
+url='https://pecl.php.net/package/APCu'
+depends=('php71')
+license=('PHP')
+conflicts=("${pkgname/71/}")
+provides=("${pkgname/71/}=${pkgver}")
+source=("https://pecl.php.net/get/apcu-$pkgver.tgz"
+        'apcu.ini')
+backup=('etc/php/conf.d/apcu.ini')
+md5sums=('0ef8be2ee8acb4dba5a66b247a254995'
+         'a353f7efe61928aa2162720789fa171f')
+
+build() {
+	cd $srcdir/apcu-$pkgver
+
+	phpize
+	./configure --prefix=/usr
+	make
+}
+
+check() {
+	cd $srcdir/apcu-$pkgver
+
+	export REPORT_EXIT_STATUS=1
+	export NO_INTERACTION=1
+	export SKIP_ONLINE_TESTS=1
+	export SKIP_SLOW_TESTS=1
+	make test
+}
+
+package() {
+	cd $srcdir/apcu-$pkgver
+
+	make INSTALL_ROOT=$pkgdir install
+
+	install -D -m644 $srcdir/apcu.ini $pkgdir/etc/php/conf.d/apcu.ini
+	install -D -m644 apc.php $pkgdir/usr/share/webapps/php-apcu/apc.php
+	install -D -m644 INSTALL $pkgdir/usr/share/doc/php-apcu/install.txt
+}

Added: trunk/apcu.ini
===================================================================
--- trunk/apcu.ini	                        (rev 0)
+++ trunk/apcu.ini	2018-01-16 08:33:10 UTC (rev 283080)
@@ -0,0 +1,3 @@
+;extension=apcu.so
+; install php-apcu-bc and enable apc.so for APC compatibility
+;extension=apc.so