[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Monday, January 22, 2018 @ 13:59:53
  Author: felixonmars
Revision: 284915

addpkg: haskell-chell-quickcheck 0.2.5.1-1

Added:
  haskell-chell-quickcheck/
  haskell-chell-quickcheck/repos/
  haskell-chell-quickcheck/trunk/
  haskell-chell-quickcheck/trunk/PKGBUILD

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Added: haskell-chell-quickcheck/trunk/PKGBUILD
===================================================================
--- haskell-chell-quickcheck/trunk/PKGBUILD	                        (rev 0)
+++ haskell-chell-quickcheck/trunk/PKGBUILD	2018-01-22 13:59:53 UTC (rev 284915)
@@ -0,0 +1,38 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=chell-quickcheck
+pkgname=haskell-chell-quickcheck
+pkgver=0.2.5.1
+pkgrel=1
+pkgdesc="QuickCheck support for the Chell testing library"
+url="https://john-millikin.com/software/chell/"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-chell' 'haskell-quickcheck' 'haskell-random')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('4879c084731112e0e17e6d82510850c119c7e5e5cde90c03ecce9ea470f94429ddd040b9346a5aa268b0ea41c5656025cc2dacfe533d370efd7162473a1ebc6e')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "license.txt" "${pkgdir}/usr/share/licenses/${pkgname}/license.txt"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/license.txt"
+}


Property changes on: haskell-chell-quickcheck/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property