[arch-commits] Commit in eolie (3 files)
Balló György
bgyorgy at archlinux.org
Tue Jan 23 16:31:40 UTC 2018
Date: Tuesday, January 23, 2018 @ 16:31:39
Author: bgyorgy
Revision: 285926
archrelease: copy trunk to community-x86_64
Added:
eolie/repos/
eolie/repos/community-x86_64/
eolie/repos/community-x86_64/PKGBUILD
(from rev 285925, eolie/trunk/PKGBUILD)
----------+
PKGBUILD | 45 +++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 45 insertions(+)
Copied: eolie/repos/community-x86_64/PKGBUILD (from rev 285925, eolie/trunk/PKGBUILD)
===================================================================
--- repos/community-x86_64/PKGBUILD (rev 0)
+++ repos/community-x86_64/PKGBUILD 2018-01-23 16:31:39 UTC (rev 285926)
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Contributor: Cédric Bellegarde cedric bellegarde at adishatz dot org
+
+pkgname=eolie
+pkgver=0.9.18
+pkgrel=2
+pkgdesc="Simple web browser for GNOME"
+arch=('x86_64')
+url="https://wiki.gnome.org/Apps/Eolie"
+license=('GPL3')
+depends=('gtkspell3' 'python-cairo' 'python-dateutil' 'python-gobject' 'webkit2gtk')
+makedepends=('git' 'gobject-introspection' 'meson')
+optdepends=('python-beautifulsoup4: Import html bookmarks'
+ 'python-crypto: Firefox Sync support'
+ 'python-fxa: Firefox Sync support'
+ 'python-pyopenssl: Show SSL certificates')
+_commit=7c6bbd3e29bd0c5caf85d1f00af1fdcf305173b1 # tags/0.9.18^0
+source=("git+https://gitlab.gnome.org/gnumdk/eolie.git#commit=$_commit"
+ "git+https://gitlab.gnome.org/gnumdk/eolie-po.git")
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+ mkdir build
+ cd $pkgname
+ git config submodule.subprojects/po.url "$srcdir/eolie-po"
+ git submodule update --init
+}
+
+build() {
+ cd build
+ meson --prefix=/usr --libexecdir=/usr/lib/$pkgname --buildtype=release ../$pkgname
+ ninja
+}
+
+package() {
+ cd build
+ DESTDIR="$pkgdir" ninja install
+}
More information about the arch-commits
mailing list