[arch-commits] Commit in pandoc-crossref/repos (2 files)

[Felix Yan]

    Date: Thursday, January 25, 2018 @ 03:43:09
  Author: felixonmars
Revision: 286732

archrelease: copy trunk to community-staging-x86_64

Added:
  pandoc-crossref/repos/community-staging-x86_64/
  pandoc-crossref/repos/community-staging-x86_64/PKGBUILD
    (from rev 286731, pandoc-crossref/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: pandoc-crossref/repos/community-staging-x86_64/PKGBUILD (from rev 286731, pandoc-crossref/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-01-25 03:43:09 UTC (rev 286732)
@@ -0,0 +1,42 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=pandoc-crossref
+pkgver=0.3.0.1
+pkgrel=13
+pkgdesc="Pandoc filter for cross-references"
+url="https://hackage.haskell.org/package/${pkgname}"
+license=("GPL2")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-data-default' 'haskell-data-accessor' 'haskell-data-accessor-template'
+         'haskell-data-accessor-transformers' 'haskell-file-embed' 'haskell-mtl'
+         'haskell-open-browser' 'haskell-optparse-applicative' 'pandoc' 'haskell-pandoc-types'
+         'haskell-roman-numerals' 'haskell-syb' 'haskell-text' 'haskell-utility-ht')
+makedepends=('ghc')
+conflicts=('haskell-pandoc-crossref')
+replaces=('haskell-pandoc-crossref')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/lierdakil/pandoc-crossref/archive/v$pkgver.tar.gz")
+sha512sums=('9484b50cb01bad33687d4787f48878899d59eeaddd6714ac324e37be5bd20a313f246cafce1d7fba36432fd99cb75f10d4efba5ebd9b0def87dc77410c912b13')
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}