[arch-commits] Commit in network-manager-applet/repos (2 files)
Jan Steffens
heftig at archlinux.org
Thu Jan 25 11:37:37 UTC 2018
Date: Thursday, January 25, 2018 @ 11:37:36
Author: heftig
Revision: 315441
archrelease: copy trunk to testing-x86_64
Added:
network-manager-applet/repos/testing-x86_64/
network-manager-applet/repos/testing-x86_64/PKGBUILD
(from rev 315440, network-manager-applet/trunk/PKGBUILD)
----------+
PKGBUILD | 74 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 74 insertions(+)
Copied: network-manager-applet/repos/testing-x86_64/PKGBUILD (from rev 315440, network-manager-applet/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2018-01-25 11:37:36 UTC (rev 315441)
@@ -0,0 +1,74 @@
+# $Id$
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Arjan Timmerman <arjan at archlinux.org>
+# Contributor: Wael Nasreddine <gandalf at siemens-mobiles.org>
+# Contributor: Tor Krill <tor at krill.nu>
+# Contributor: Will Rea <sillywilly at gmail.com>
+
+pkgbase=network-manager-applet
+pkgname=(nm-connection-editor network-manager-applet)
+pkgdesc="Applet for managing network connections"
+url="https://wiki.gnome.org/Projects/NetworkManager/"
+pkgver=1.8.11dev+12+ga37483c1
+pkgrel=1
+arch=(x86_64)
+license=(GPL2 LGPL2.1)
+depends=(libnm-glib libgudev gtk3 mobile-broadband-provider-info iso-codes gcr)
+makedepends=(libsecret libnotify libmm-glib intltool gobject-introspection git gtk-doc meson)
+options=(!emptydirs)
+_commit=a37483c1a364ef3cc1cfa29e7ad51ca108d75674 # master
+source=("git+https://git.gnome.org/browse/network-manager-applet#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgbase
+ git describe --tags | sed 's/-dev/dev/;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgbase
+}
+
+build() {
+ arch-meson $pkgbase build -Dselinux=false
+ ninja -C build
+}
+
+check() {
+ cd build
+ meson test
+}
+
+package_nm-connection-editor() {
+ pkgdesc="NetworkManager GUI connection editor and widgets"
+ provides=("libnm-gtk=$pkgver-$pkgrel" "libnma=$pkgver-$pkgrel")
+ conflicts=(libnm-gtk)
+ replaces=(libnm-gtk)
+
+ DESTDIR="$pkgdir" ninja -C build install
+
+### Split network-manager-applet
+ mkdir -p nma/etc/xdg nma/usr/bin \
+ nma/usr/share/{applications,icons/hicolor/22x22/apps,man/man1,nm-applet}
+
+ cd nma
+ mv "$pkgdir"/etc/xdg/autostart etc/xdg/
+ mv "$pkgdir"/usr/bin/nm-applet usr/bin/
+ mv "$pkgdir"/usr/share/GConf usr/share/
+
+ cd usr/share
+ mv "$pkgdir"/usr/share/applications/nm-applet.desktop applications/
+ mv "$pkgdir"/usr/share/man/man1/nm-applet.1 man/man1/
+
+ cd icons/hicolor/22x22
+ mv "$pkgdir"/usr/share/icons/hicolor/22x22/apps/nm-{adhoc,mb-roam,wwan-tower}.png apps/
+ mv "$pkgdir"/usr/share/icons/hicolor/22x22/apps/nm-{secure,vpn-active}-lock.png apps/
+ mv "$pkgdir"/usr/share/icons/hicolor/22x22/apps/nm-{signal,tech}-*.png apps/
+ mv "$pkgdir"/usr/share/icons/hicolor/22x22/apps/nm-*connecting*.png apps/
+}
+
+package_network-manager-applet() {
+ depends=(nm-connection-editor libmm-glib libnotify libsecret networkmanager)
+ mv nma/* "$pkgdir"
+}
Property changes on: network-manager-applet/repos/testing-x86_64/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property
Added: svn:mergeinfo
More information about the arch-commits
mailing list