[arch-commits] Commit in hledger/repos (2 files)

[Felix Yan]

    Date: Tuesday, July 3, 2018 @ 13:34:08
  Author: felixonmars
Revision: 350992

archrelease: copy trunk to community-staging-x86_64

Added:
  hledger/repos/community-staging-x86_64/
  hledger/repos/community-staging-x86_64/PKGBUILD
    (from rev 350991, hledger/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: hledger/repos/community-staging-x86_64/PKGBUILD (from rev 350991, hledger/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-07-03 13:34:08 UTC (rev 350992)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hledger
+pkgver=1.9.1
+pkgrel=27
+pkgdesc="Command-line interface for the hledger accounting tool"
+url="http://hledger.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-base-compat' 'haskell-cmdargs' 'haskell-csv'
+         'haskell-data-default' 'haskell-decimal' 'haskell-diff' 'haskell-file-embed'
+         'haskell-hashable' 'haskell-here' 'haskell-hledger-lib' 'haskell-hunit' 'haskell-lucid'
+         'haskell-megaparsec' 'haskell-old-time' 'haskell-pretty-show'
+         'haskell-regex-tdfa' 'haskell-safe' 'haskell-shakespeare' 'haskell-split' 'haskell-tabular'
+         'haskell-temporary' 'haskell-unordered-containers' 'haskell-utf8-string'
+         'haskell-utility-ht' 'haskell-wizards')
+makedepends=('ghc' 'haskell-test-framework' 'haskell-test-framework-hunit')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('d1d0abbee555e152a713e2fcfc185e196e705f73dcc6f94106ddfc9695412ae8bfbe8b487ae09a5a8a94338b85b7466fa9c28ce81e8a56e46c4fab0a7714a5eb')
+
+prepare() {
+    # It does nothing
+    sed -e '/mtl-compat/d' \
+        -i ${pkgname}-${pkgver}/${pkgname}.cabal
+}
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fterminfo -fthreaded
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}