[arch-commits] Commit in python-billiard/repos (2 files)

Eli Schwartz eschwartz at archlinux.org
Wed Jul 4 19:15:21 UTC 2018


    Date: Wednesday, July 4, 2018 @ 19:15:21
  Author: eschwartz
Revision: 352085

archrelease: copy trunk to community-staging-x86_64

Added:
  python-billiard/repos/community-staging-x86_64/
  python-billiard/repos/community-staging-x86_64/PKGBUILD
    (from rev 352084, python-billiard/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: python-billiard/repos/community-staging-x86_64/PKGBUILD (from rev 352084, python-billiard/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-07-04 19:15:21 UTC (rev 352085)
@@ -0,0 +1,53 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Benjamin A. Shelton <zancarius at gmail.com>
+# Source: https://github.com/zancarius/archlinux-pkgbuilds
+
+pkgbase=python-billiard
+pkgname=('python-billiard' 'python2-billiard')
+pkgver=3.5.0.3
+pkgrel=2
+pkgdesc="Python multiprocessing fork with improvements and bugfixes."
+arch=('x86_64')
+url="https://pypi.org/project/billiard/"
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-case' 'python2-case')
+source=("https://pypi.io/packages/source/b/billiard/billiard-$pkgver.tar.gz")
+sha512sums=('f3a98e9b7af8c0b5741bcea915c0ff8d6e32e26d79637d14fc09ea85dd80693ea8205e13ac2d86e5035c377fdd6d769a2647b005dc10af8b106c75464458a808')
+
+prepare() {
+  cp -a billiard-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/billiard-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/billiard-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/billiard-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/billiard-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-billiard() {
+  depends=('python')
+
+  cd "$srcdir"/billiard-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm0664 "$srcdir"/billiard-$pkgver/LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-billiard() {
+  depends=('python2')
+
+  cd "$srcdir"/billiard-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm0664 "$srcdir"/billiard-$pkgver/LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}



More information about the arch-commits mailing list