[arch-commits] Commit in hedgewars/repos (2 files)

[Felix Yan]

    Date: Wednesday, July 4, 2018 @ 20:57:34
  Author: felixonmars
Revision: 352201

archrelease: copy trunk to community-staging-x86_64

Added:
  hedgewars/repos/community-staging-x86_64/
  hedgewars/repos/community-staging-x86_64/PKGBUILD
    (from rev 352200, hedgewars/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: hedgewars/repos/community-staging-x86_64/PKGBUILD (from rev 352200, hedgewars/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-07-04 20:57:34 UTC (rev 352201)
@@ -0,0 +1,55 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Tinxy <arch at tinx dot eu>
+
+pkgname=hedgewars
+pkgver=0.9.24.1
+pkgrel=29
+pkgdesc="Turn-based strategy artillery game similiar to Worms"
+arch=('x86_64')
+url="https://hedgewars.org"
+license=('GPL' 'custom')
+depends=('qt5-base' 'sdl2' 'sdl2_mixer' 'sdl2_image' 'sdl2_net' 'sdl2_ttf' 'lua51' 'ffmpeg' 'glut'
+         'physfs' 'ghc-libs' 'haskell-entropy' 'haskell-sha' 'haskell-random' 'haskell-regex-tdfa'
+         'haskell-sandi' 'haskell-hslogger' 'haskell-utf8-string' 'haskell-vector')
+makedepends=('fpc' 'cmake' 'qt5-tools' 'ghc' 'haskell-network' 'haskell-bytestring-show'
+             'haskell-zlib' 'haskell-base-prelude' 'imagemagick' 'mesa')
+source=("https://www.hedgewars.org/download/releases/hedgewars-src-$pkgver.tar.bz2")
+sha512sums=('b0b166c807e0d08a763e5e88e178d6e629baa420685bbfe381db7b5ecf003175892f8c2e3b75f1f6d7663335bd5b417d1a2afdc89b9d56b348b056ee3490ed2f')
+
+prepare() {
+  cd hedgewars-src-$pkgver
+  sed -i 's|set(ghc_flags|set(ghc_flags -dynamic|' gameServer/CMakeLists.txt
+}
+
+build() {
+  cd hedgewars-src-$pkgver
+  cmake \
+    -DCMAKE_BUILD_TYPE="Release" \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DDATA_INSTALL_DIR=/usr/share/hedgewars \
+    -DNOSERVER=0 \
+    .
+  make
+
+  # resize icon
+  for _size in 16 32 48 64 128 256; do
+    convert misc/hedgewars.png -resize ${_size}x${_size} hedgewars_${_size}.png
+  done
+}
+
+package() {
+  cd hedgewars-src-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -D -m644 Fonts_LICENSE.txt "$pkgdir"/usr/share/licenses/${pkgname}/Fonts_LICENSE.txt
+
+  # install icons
+  install -D -m644 misc/hedgewars.png "$pkgdir"/usr/share/icons/hicolor/512x512/apps/hedgewars.png
+  for _size in 16 32 48 64 128 256; do
+    install -D -m644 hedgewars_${_size}.png "$pkgdir"/usr/share/icons/hicolor/${_size}x${_size}/apps/hedgewars.png
+  done
+  rm -rf "$pkgdir"/usr/share/pixmaps
+
+  install -D -m644 share/hedgewars/Data/misc/hedgewars.desktop "$pkgdir"/usr/share/applications/hedgewars.desktop
+}