[arch-commits] Commit in haskell-persistent/repos (2 files)

[Felix Yan]

    Date: Thursday, July 5, 2018 @ 21:49:54
  Author: felixonmars
Revision: 353193

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-persistent/repos/community-staging-x86_64/
  haskell-persistent/repos/community-staging-x86_64/PKGBUILD
    (from rev 353192, haskell-persistent/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-persistent/repos/community-staging-x86_64/PKGBUILD (from rev 353192, haskell-persistent/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-07-05 21:49:54 UTC (rev 353193)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=persistent
+pkgname=haskell-persistent
+pkgver=2.8.2
+pkgrel=36
+pkgdesc="Type-safe, multi-backend data serialization"
+url="http://www.yesodweb.com/book/persistent"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-base64-bytestring'
+         'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-conduit' 'haskell-fast-logger'
+         'haskell-http-api-data' 'haskell-monad-logger' 'haskell-old-locale' 'haskell-path-pieces'
+         'haskell-resource-pool' 'haskell-resourcet' 'haskell-scientific' 'haskell-silently'
+         'haskell-src-meta' 'haskell-tagged' 'haskell-unordered-containers' 'haskell-unliftio-core'
+         'haskell-vector' 'haskell-void')
+makedepends=('ghc' 'haskell-hspec')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('238203dafac06ed43a599d0be1eb4c7931a41734facb02174dd02d3789ad3afe39f42bdb7907aeedd42caf2d63e483066b5f43315826563d2a67fd8c8e7f4936')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-nooverlap
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}