[arch-commits] Commit in haskell-skylighting-core/repos (2 files)

[Felix Yan]

    Date: Friday, July 6, 2018 @ 14:02:46
  Author: felixonmars
Revision: 353670

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-skylighting-core/repos/community-staging-x86_64/
  haskell-skylighting-core/repos/community-staging-x86_64/PKGBUILD
    (from rev 353669, haskell-skylighting-core/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-skylighting-core/repos/community-staging-x86_64/PKGBUILD (from rev 353669, haskell-skylighting-core/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-07-06 14:02:46 UTC (rev 353670)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=skylighting-core
+pkgname=haskell-skylighting-core
+pkgver=0.7.2
+pkgrel=12
+pkgdesc="Syntax highlighting library"
+url="https://github.com/jgm/skylighting"
+license=('custom:BSD3')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-terminal' 'haskell-attoparsec'
+         'haskell-base64-bytestring' 'haskell-blaze-html' 'haskell-case-insensitive'
+         'haskell-colour' 'haskell-hxt' 'haskell-regex-pcre' 'haskell-safe'
+         'haskell-utf8-string')
+makedepends=('ghc' 'haskell-diff' 'haskell-hunit' 'haskell-pretty-show' 'haskell-quickcheck'
+             'haskell-random' 'haskell-tasty' 'haskell-tasty-golden' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('09fa3a44a08da045b394dbb4f526f0ca6cdb35bedde3619c21269d4e8bd4534a39a62d4b6fc5130d62f483bfe8e94eb4523b92cfac4fe0d5c2f7b49354ce5642')
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fexecutable -fsystem-pcre
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+    
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}