[arch-commits] Commit in libsavitar/repos (2 files)

[Felix Yan]

    Date: Sunday, July 8, 2018 @ 08:26:00
  Author: felixonmars
Revision: 354681

archrelease: copy trunk to community-staging-x86_64

Added:
  libsavitar/repos/community-staging-x86_64/
  libsavitar/repos/community-staging-x86_64/PKGBUILD
    (from rev 354680, libsavitar/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: libsavitar/repos/community-staging-x86_64/PKGBUILD (from rev 354680, libsavitar/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-07-08 08:26:00 UTC (rev 354681)
@@ -0,0 +1,39 @@
+# Maintainer: Jelle van der Waa <jelle at archlinux.org>
+# Contributor: neodarz <neodarz at neodarz.net>
+
+pkgname=libsavitar
+pkgver=3.3.0
+pkgrel=2
+pkgdesc="C++ implementation of 3mf loading with SIP python bindings"
+arch=('x86_64')
+url="https://github.com/Ultimaker/libsavitar"
+license=('AGPL')
+depends=('python' 'pugixml')
+makedepends=('cmake' 'python-sip')
+source=($pkgname-$pkgver.tar.gz::https://github.com/Ultimaker/libSavitar//archive/${pkgver}.tar.gz
+        pugixml.patch::https://github.com/Ultimaker/libSavitar/commit/91aa70c6320461ae65600dce954b5ffb905b7039.patch)
+
+prepare() {
+  cd "libSavitar-${pkgver}"
+  sed -i 's,DESTINATION lib/python${PYTHON_VERSION_MAJOR}/dist-packages,DESTINATION lib/python${PYTHON_VERSION_MAJOR}.${PYTHON_VERSION_MINOR}/site-packages,g' CMakeLists.txt
+  sed -i 's,DESTINATION lib/python${PYTHON_VERSION_MAJOR}/dist-packages/cura),DESTINATION lib/python${PYTHON_VERSION_MAJOR}.${PYTHON_VERSION_MINOR}/site-packages/cura),g' CMakeLists.txt
+
+  patch -Np1 -i $srcdir/pugixml.patch
+}
+
+build() {
+  cd "libSavitar-${pkgver}"
+  mkdir  build && cd build
+  cmake .. \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+    -DCMAKE_BUILD_TYPE=Release
+  make
+}
+
+package() {
+  cd "libSavitar-${pkgver}/build"
+  make DESTDIR="${pkgdir}" install
+}
+md5sums=('0c8a9f2a215cc9ef3d2f2007091076f6'
+         '4df1132abcbc1955adac77d4713dfdf7')