[arch-commits] Commit in python-jose/repos (2 files)

[Felix Yan]

    Date: Sunday, July 8, 2018 @ 12:54:41
  Author: felixonmars
Revision: 354833

archrelease: copy trunk to community-staging-any

Added:
  python-jose/repos/community-staging-any/
  python-jose/repos/community-staging-any/PKGBUILD
    (from rev 354831, python-jose/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: python-jose/repos/community-staging-any/PKGBUILD (from rev 354831, python-jose/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2018-07-08 12:54:41 UTC (rev 354833)
@@ -0,0 +1,58 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-jose
+pkgname=('python-jose' 'python2-jose')
+pkgver=3.0.0
+pkgrel=2
+pkgdesc="A JOSE implementation in Python"
+arch=('any')
+license=('MIT')
+url="https://github.com/mpdavis/python-jose"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-rsa' 'python2-rsa'
+             'python-six' 'python2-six' 'python-ecdsa' 'python2-ecdsa' 'python-future'
+             'python2-future')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python-cryptography'
+              'python2-cryptography' 'python-pycryptodome' 'python2-pycryptodome')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/mpdavis/python-jose/archive/$pkgver.tar.gz")
+sha512sums=('c989db6783434d3b1163fb2adac1e8b4f3ca7e693ebcde7e309d2632a9b1f959538c513a225029d3c647eaa1f1b407cfae69e56d65c15c8edfdb0113e5b0f41b')
+
+prepare() {
+  cp -a python-jose-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/python-jose-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/python-jose-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/python-jose-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/python-jose-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-jose() {
+  depends=('python-rsa' 'python-six' 'python-ecdsa' 'python-future')
+  optdepends=('python-cryptography: one option for better performance'
+              'python-pycryptodome: one option for better performance')
+
+  cd python-jose-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-jose() {
+  depends=('python2-rsa' 'python2-six' 'python2-ecdsa' 'python2-future')
+  optdepends=('python2-cryptography: one option for better performance'
+              'python2-pycryptodome: one option for better performance')
+
+  cd python-jose-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}