[arch-commits] Commit in sip/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Antonio Rojas
arojas at archlinux.org
Sun Jul 8 14:07:41 UTC 2018
Date: Sunday, July 8, 2018 @ 14:07:41
Author: arojas
Revision: 328074
archrelease: copy trunk to testing-x86_64
Added:
sip/repos/testing-x86_64/
sip/repos/testing-x86_64/PKGBUILD
(from rev 328073, sip/trunk/PKGBUILD)
----------+
PKGBUILD | 91 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 91 insertions(+)
Copied: sip/repos/testing-x86_64/PKGBUILD (from rev 328073, sip/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2018-07-08 14:07:41 UTC (rev 328074)
@@ -0,0 +1,91 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Douglas Soares de Andrade <douglas at archlinux.org>
+# Contributor: riai <riai at bigfoot.com>, Ben <ben at benmazer.net>
+
+pkgbase=sip
+pkgname=('sip' 'python-sip' 'python2-sip' 'python-sip-pyqt5' 'python2-sip-pyqt5')
+pkgver=4.19.12
+pkgrel=1
+arch=('x86_64')
+url='http://www.riverbankcomputing.com/software/sip/intro'
+license=('custom:"sip"')
+makedepends=('python' 'python2')
+source=("http://sourceforge.net/projects/pyqt/files/sip/sip-$pkgver/sip-$pkgver.tar.gz")
+sha256sums=('24617fc31b983df075500ecac0e99d2fb48bf63ba82d4a17518659e571923822')
+
+prepare() {
+ mkdir -p build{,-py2,-pyqt5,-pyqt5-py2}
+}
+
+build() {
+ cd "$srcdir"/build
+ python ../sip-$pkgver/configure.py CFLAGS="$CFLAGS" LFLAGS="$LDFLAGS"
+ make
+
+ cd "$srcdir"/build-py2
+ python2 ../sip-$pkgver/configure.py CFLAGS="$CFLAGS" LFLAGS="$LDFLAGS"
+ make
+
+ cd "$srcdir"/build-pyqt5
+ python ../sip-$pkgver/configure.py CFLAGS="$CFLAGS" LFLAGS="$LDFLAGS" --sip-module PyQt5.sip
+ make
+
+ cd "$srcdir"/build-pyqt5-py2
+ python2 ../sip-$pkgver/configure.py CFLAGS="$CFLAGS" LFLAGS="$LDFLAGS" --sip-module PyQt5.sip
+ make
+}
+
+package_sip() {
+ pkgdesc="A tool that makes it easy to create Python bindings for C and C++ libraries"
+ depends=('glibc')
+
+ cd build
+ make DESTDIR="$pkgdir" install -C sipgen
+
+ install -Dm644 ../sip-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python-sip() {
+ pkgdesc="Python 3.x SIP bindings for C and C++ libraries"
+ depends=('python')
+
+ cd build
+ make DESTDIR="$pkgdir" install
+ rm -r "$pkgdir"/usr/bin # conflicts with sip
+
+ install -Dm644 ../sip-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-sip() {
+ pkgdesc="Python 2.x SIP bindings for C and C++ libraries"
+ depends=('sip' 'python2')
+
+ cd build-py2
+ make DESTDIR="$pkgdir" install
+ rm -r "$pkgdir"/usr/bin # conflicts with sip
+
+ install -Dm644 ../sip-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python-sip-pyqt5() {
+ pkgdesc="Python 3.x SIP bindings for C and C++ libraries (PyQt5 version)"
+ depends=('python')
+
+ cd build-pyqt5
+ make DESTDIR="$pkgdir" install -C siplib
+
+ install -Dm644 ../sip-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-sip-pyqt5() {
+ pkgdesc="Python 2.x SIP bindings for C and C++ libraries (PyQt5 version)"
+ depends=('python2')
+
+ cd build-pyqt5-py2
+ make DESTDIR="$pkgdir" install -C siplib
+
+ install -Dm644 ../sip-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
More information about the arch-commits
mailing list