[arch-commits] Commit in haskell-hledger-lib/repos (2 files)

[Felix Yan]

    Date: Tuesday, July 10, 2018 @ 16:01:04
  Author: felixonmars
Revision: 356241

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hledger-lib/repos/community-staging-x86_64/
  haskell-hledger-lib/repos/community-staging-x86_64/PKGBUILD
    (from rev 356240, haskell-hledger-lib/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: haskell-hledger-lib/repos/community-staging-x86_64/PKGBUILD (from rev 356240, haskell-hledger-lib/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-07-10 16:01:04 UTC (rev 356241)
@@ -0,0 +1,54 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=hledger-lib
+pkgname=haskell-hledger-lib
+pkgver=1.10
+pkgrel=2
+pkgdesc="Core data types, parsers and functionality for the hledger accounting tools"
+url="http://hledger.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-base-compat-batteries' 'haskell-blaze-markup'
+         'haskell-cmdargs' 'haskell-csv' 'haskell-data-default' 'haskell-decimal' 'haskell-extra'
+         'haskell-hashtables' 'haskell-megaparsec' 'haskell-old-time' 'haskell-pretty-show'
+         'haskell-regex-tdfa' 'haskell-safe' 'haskell-split' 'haskell-tabular' 'haskell-uglymemo'
+         'haskell-utf8-string' 'haskell-hunit')
+makedepends=('ghc' 'haskell-doctest' 'haskell-easytest' 'haskell-glob' 'haskell-parser-combinators'
+             'haskell-test-framework' 'haskell-test-framework-hunit')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('4ef569d05e29c49ecff4c61b71bf3e1992fd3811c3663570eabb0370065b066f4b3323f714d376ac0f49841fd0a3c739ed4a8a21c00da0f94982c57cf0507ba7')
+
+prepare() {
+    # It does nothing
+    sed -e '/mtl-compat/d' \
+        -i ${_hkgname}-${pkgver}/${_hkgname}.cabal
+}
+
+build() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd "${srcdir}/${_hkgname}-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}