[arch-commits] Commit in python-gevent/repos (2 files)

[Felix Yan]

    Date: Tuesday, July 17, 2018 @ 18:18:09
  Author: felixonmars
Revision: 361096

archrelease: copy trunk to community-staging-x86_64

Added:
  python-gevent/repos/community-staging-x86_64/
  python-gevent/repos/community-staging-x86_64/PKGBUILD
    (from rev 361095, python-gevent/trunk/PKGBUILD)

----------+
 PKGBUILD |   78 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)

Copied: python-gevent/repos/community-staging-x86_64/PKGBUILD (from rev 361095, python-gevent/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2018-07-17 18:18:09 UTC (rev 361096)
@@ -0,0 +1,78 @@
+# $Id: PKGBUILD 70305 2012-05-04 08:21:08Z mtorromeo $
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Ralf Schmitt <ralf at systemexit.de>
+
+pkgbase=python-gevent
+pkgname=(python-gevent python2-gevent)
+pkgver=1.3.5
+pkgrel=1
+arch=('x86_64')
+pkgdesc="Python network library that uses greenlet and libev for easy and scalable concurrency"
+license=("MIT")
+url="http://www.gevent.org/"
+makedepends=('python-greenlet' 'python2-greenlet' 'cython' 'cython2')
+checkdepends=('lsof' 'python-perf' 'python2-perf' 'python2-virtualenv' 'python-objgraph'
+              'python2-objgraph' 'python-zope-interface' 'python2-zope-interface' 'python-dnspython'
+              'python2-dnspython' 'python-requests' 'python2-requests' 'python-zope-event'
+              'python2-zope-event' 'python2-mock')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/gevent/gevent/archive/$pkgver.tar.gz")
+sha512sums=('d0a97103c45fb61e8bbac734d29b6b2a01d317c279e48138e4cb52b6d1486cb29a54f6d5cac85ba067c95fd142e4a9cad94c2422373c921b34a813d0ba3b7759')
+
+prepare() {
+  sed -e 's/C.UTF-8/en_US.UTF-8/' -e '/@which/d' -i gevent-$pkgver/Makefile
+
+  cp -a gevent-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/gevent-$pkgver
+
+  EMBED=1 \
+  CYTHON=cython \
+  PYTHON=python \
+  python setup.py build
+
+  cd "$srcdir"/gevent-$pkgver-py2
+
+  EMBED=1 \
+  CYTHON=cython2 \
+  PYTHON=python2 \
+  python2 setup.py build
+}
+
+check() {
+  (
+    cd "$srcdir"/gevent-$pkgver
+    pyvenv "$srcdir/pyvenv" --system-site-packages
+    . "$srcdir/pyvenv/bin/activate"
+    export PYTHONPATH="$PYTHONPATH:/usr/lib/python3.6/site-packages"
+    python setup.py install
+    make bench alltest
+  ) || warning "Tests failed"
+
+  (
+    cd "$srcdir"/gevent-$pkgver-py2
+    virtualenv2 "$srcdir/pyvenv" --system-site-packages
+    . "$srcdir/pyvenv/bin/activate"
+    export PYTHONPATH="$PYTHONPATH:/usr/lib/python2.7/site-packages"
+    python setup.py install
+    PYTHON=python2 make bench alltest
+  ) || warning "Tests failed"
+}
+
+package_python-gevent() {
+  depends=('python-greenlet')
+
+  cd gevent-$pkgver
+  python setup.py install -O1 --root="$pkgdir"
+  install -Dm0644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-gevent() {
+  depends=('python2-greenlet')
+
+  cd gevent-$pkgver-py2
+  python2 setup.py install -O1 --root="$pkgdir"
+  install -Dm0644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}