[arch-commits] Commit in python-zope-testing/repos (2 files)

[Evangelos Foutras]

    Date: Wednesday, July 18, 2018 @ 01:45:37
  Author: foutrelis
Revision: 361199

archrelease: copy trunk to community-staging-any

Added:
  python-zope-testing/repos/community-staging-any/
  python-zope-testing/repos/community-staging-any/PKGBUILD
    (from rev 361198, python-zope-testing/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: python-zope-testing/repos/community-staging-any/PKGBUILD (from rev 361198, python-zope-testing/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2018-07-18 01:45:37 UTC (rev 361199)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-zope-testing
+pkgname=('python-zope-testing' 'python2-zope-testing')
+pkgver=4.6.2
+pkgrel=2
+pkgdesc="Zope testing helpers"
+arch=('any')
+url="https://github.com/zopefoundation/zope.testing"
+license=('ZPL')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-zope-interface'
+             'python2-zope-interface' 'python-zope-exceptions' 'python2-zope-exceptions')
+checkdepends=('python-nose' 'python2-nose')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/zopefoundation/zope.testing/archive/$pkgver.tar.gz")
+sha256sums=('SKIP')
+
+prepare() {
+  cp -a zope.testing-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir/zope.testing-$pkgver"
+  python setup.py build
+
+  cd "$srcdir/zope.testing-$pkgver-py2"
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir/zope.testing-$pkgver"
+  python setup.py test
+
+  cd "$srcdir/zope.testing-$pkgver-py2"
+  python2 setup.py test
+}
+
+package_python-zope-testing() {
+  depends=('python-setuptools' 'python-zope-interface' 'python-zope-exceptions')
+
+  cd "$srcdir/zope.testing-$pkgver"
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-zope-testing() {
+  depends=('python2-setuptools' 'python2-zope-interface' 'python2-zope-exceptions')
+
+  cd "$srcdir/zope.testing-$pkgver-py2"
+  python2 setup.py install --root="$pkgdir" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et: