[arch-commits] Commit in python-stestr/repos (2 files)
Evangelos Foutras
foutrelis at archlinux.org
Wed Jul 18 01:59:18 UTC 2018
Date: Wednesday, July 18, 2018 @ 01:59:18
Author: foutrelis
Revision: 361219
archrelease: copy trunk to community-staging-any
Added:
python-stestr/repos/community-staging-any/
python-stestr/repos/community-staging-any/PKGBUILD
(from rev 361218, python-stestr/trunk/PKGBUILD)
----------+
PKGBUILD | 70 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 70 insertions(+)
Copied: python-stestr/repos/community-staging-any/PKGBUILD (from rev 361218, python-stestr/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD (rev 0)
+++ community-staging-any/PKGBUILD 2018-07-18 01:59:18 UTC (rev 361219)
@@ -0,0 +1,70 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Simon Sapin <simon dot sapin at exyr dot org>
+# Contributor: Kyle Keen <keenerd at gmail.com>
+
+pkgbase=python-stestr
+pkgname=(python-stestr python2-stestr)
+pkgver=2.1.0
+pkgrel=2
+pkgdesc="A test runner runner similar to testrepository"
+url="http://stestr.readthedocs.io/en/latest/"
+license=('Apache')
+arch=('any')
+makedepends=('python-future' 'python2-future' 'python-pbr' 'python2-pbr' 'python-cliff'
+ 'python2-cliff' 'python-subunit' 'python2-subunit' 'python-fixtures' 'python2-fixtures'
+ 'python-testtools' 'python2-testtools' 'python-yaml' 'python2-yaml' 'python-voluptuous'
+ 'python2-voluptuous')
+checkdepends=('python-hacking' 'python2-hacking' 'python-sphinx' 'python2-sphinx' 'python-mock'
+ 'python2-mock' 'python-subunit2sql' 'python2-subunit2sql' 'python-coverage'
+ 'python2-coverage' 'python-ddt' 'python2-ddt')
+source=("https://pypi.io/packages/source/s/stestr/stestr-$pkgver.tar.gz")
+sha512sums=('a99d0659da0ca2b86703529df9ef6d135578bd8374a2afcbd10bd96f24f5e6dd1dacd5929d96a083881f1db2a930b039d9045348a0298d84d2480c6c9a75d1f7')
+
+prepare() {
+ cp -a stestr-$pkgver{,-py2}
+}
+
+build() {
+ cd "$srcdir"/stestr-$pkgver
+ python setup.py build
+
+ cd "$srcdir"/stestr-$pkgver-py2
+ python2 setup.py build
+}
+
+check() {
+ cd "$srcdir"/stestr-$pkgver
+ python setup.py install --root="$PWD/tmp_install" --optimize=1
+ (
+ export PYTHONPATH="$PWD/tmp_install/usr/lib/python3.6/site-packages"
+ export PATH="$PWD/tmp_install/usr/bin:$PATH"
+ stestr run || warning "Tests failed"
+ )
+
+ cd "$srcdir"/stestr-$pkgver-py2
+ python2 setup.py install --root="$PWD/tmp_install" --optimize=1
+ (
+ export PYTHONPATH="$PWD/tmp_install/usr/lib/python2.7/site-packages"
+ export PATH="$PWD/tmp_install/usr/bin:$PATH"
+ stestr run || warning "Tests failed"
+ )
+}
+
+package_python-stestr() {
+ depends=('python-future' 'python-cliff' 'python-pbr' 'python-subunit' 'python-fixtures'
+ 'python-testtools' 'python-yaml' 'python-voluptuous')
+
+ cd stestr-$pkgver
+ python setup.py install --root="$pkgdir" --optimize=1
+}
+
+package_python2-stestr() {
+ depends=('python2-future' 'python2-cliff' 'python2-pbr' 'python2-subunit' 'python2-fixtures'
+ 'python2-testtools' 'python2-yaml' 'python2-voluptuous')
+
+ cd stestr-$pkgver-py2
+ python2 setup.py install --root="$pkgdir" --optimize=1
+
+ mv "$pkgdir"/usr/bin/stestr{,2}
+}
More information about the arch-commits
mailing list