[arch-commits] Commit in qtcreator/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Thursday, July 19, 2018 @ 17:31:03
  Author: arojas
Revision: 329065

archrelease: copy trunk to staging-x86_64

Added:
  qtcreator/repos/staging-x86_64/
  qtcreator/repos/staging-x86_64/PKGBUILD
    (from rev 329064, qtcreator/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: qtcreator/repos/staging-x86_64/PKGBUILD (from rev 329064, qtcreator/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2018-07-19 17:31:03 UTC (rev 329065)
@@ -0,0 +1,60 @@
+# $Id$
+# Maintainer: Sven-Hendrik Haase <sh at lutzhaase.com>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Imanol Celaya <ornitorrincos at archlinux-es.org>
+# Contributor: Lukas Jirkovsky <l.jirkovsky at gmail.com>
+# Contributor: Dan Vratil <progdan at progdansoft.com>
+# Contributor: thotypous <matiasΘarchlinux-br·org>
+# Contributor: delor <bartekpiech gmail com>
+
+pkgname=qtcreator
+pkgver=4.7.0
+_clangver=6.0.1
+pkgrel=1
+pkgdesc='Lightweight, cross-platform integrated development environment'
+arch=(x86_64)
+url='http://qt-project.org'
+license=(LGPL)
+depends=(qt5-tools qt5-quickcontrols qt5-quickcontrols2 qt5-webengine clang=$_clangver qbs)
+makedepends=(git mesa llvm)
+options=(docs)
+optdepends=('qt5-doc: integrated Qt documentation'
+            'qt5-examples: welcome page examples'
+            'qt5-translations: for other languages'
+            'gdb: debugger'
+            'cmake: cmake project support'
+            'x11-ssh-askpass: ssh support'
+            'git: git support'
+            'mercurial: mercurial support'
+            'bzr: bazaar support'
+            'valgrind: analyze support')
+source=("http://download.qt.io/official_releases/qtcreator/${pkgver%.*}/$pkgver/qt-creator-opensource-src-$pkgver.tar.xz")
+sha256sums=('4b19870bf8d43665deac73a0522a1459d19f5b18b6f52030bb7fbc82d90b759b')
+
+prepare() {
+  mkdir -p build
+
+  cd qt-creator-opensource-src-$pkgver
+  # fix hardcoded libexec path
+  sed -e 's|libexec\/qtcreator|lib\/qtcreator|g' -i qtcreator.pri
+  # use system qbs
+  rm -r src/shared/qbs
+}
+
+build() {
+  cd build
+
+  qmake LLVM_INSTALL_DIR=/usr QBS_INSTALL_DIR=/usr CONFIG+=journald QMAKE_CFLAGS_ISYSTEM=-I \
+    DEFINES+=QBS_ENABLE_PROJECT_FILE_UPDATES "$srcdir"/qt-creator-opensource-src-$pkgver/qtcreator.pro
+  make
+  make docs
+}
+
+package() {
+  cd build
+
+  make INSTALL_ROOT="$pkgdir/usr/" install
+  make INSTALL_ROOT="$pkgdir/usr/" install_docs
+
+  install -Dm644 "$srcdir"/qt-creator-opensource-src-$pkgver/LICENSE.GPL3-EXCEPT "$pkgdir"/usr/share/licenses/qtcreator/LICENSE.GPL3-EXCEPT
+}