[arch-commits] Commit in vulkan-tools/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Laurent Carlier
lcarlier at archlinux.org
Fri Jul 20 06:38:00 UTC 2018
Date: Friday, July 20, 2018 @ 06:38:00
Author: lcarlier
Revision: 329084
archrelease: copy trunk to staging-x86_64
Added:
vulkan-tools/repos/staging-x86_64/
vulkan-tools/repos/staging-x86_64/PKGBUILD
(from rev 329083, vulkan-tools/trunk/PKGBUILD)
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Copied: vulkan-tools/repos/staging-x86_64/PKGBUILD (from rev 329083, vulkan-tools/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2018-07-20 06:38:00 UTC (rev 329084)
@@ -0,0 +1,52 @@
+# $Id$
+# Maintainer: Laurent Carlier <lordheavym at gmail.com>
+
+pkgname=vulkan-tools
+pkgver=1.1.79+6811+b7c389c9
+pkgrel=1
+arch=(x86_64)
+url="https://www.khronos.org/vulkan/"
+pkgdesc="Vulkan Utilities and Tools"
+license=('custom')
+depends=(gcc-libs libxcb vulkan-icd-loader)
+makedepends=(git cmake python vulkan-headers libx11 wayland)
+source=("git+https://github.com/KhronosGroup/Vulkan-Tools.git#commit=b7c389c9d3efe5cea722eb7395fb70529dd27566")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd "${srcdir}/Vulkan-Tools"
+
+ echo 1.1.79+$(git rev-list --count HEAD)+$(git rev-parse --short HEAD)
+}
+
+build() {
+ cd "${srcdir}/Vulkan-Tools"
+
+ rm -rf build ; mkdir build ; cd build
+ cmake \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_SYSCONFDIR=/etc \
+ -DCMAKE_INSTALL_DATADIR=/usr/share \
+ -DCMAKE_SKIP_RPATH=True \
+ -DBUILD_WSI_XCB_SUPPORT=On \
+ -DBUILD_WSI_XLIB_SUPPORT=On \
+ -DBUILD_WSI_WAYLAND_SUPPORT=On \
+ -DBUILD_WSI_MIR_SUPPORT=Off \
+ -DBUILD_CUBE=ON \
+ -DBUILD_VULKANINFO=ON \
+ -DBUILD_ICD=OFF \
+ -DCMAKE_BUILD_TYPE=Release \
+ ..
+ make
+}
+
+package() {
+ groups=('vulkan-devel')
+
+ cd "${srcdir}/Vulkan-Tools/build"
+
+ make DESTDIR="${pkgdir}" install
+
+ install -dm755 ${pkgdir}/usr/share/licenses/${pkgname}
+ install -m644 ../LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/
+}
More information about the arch-commits
mailing list