[arch-commits] Commit in python-celery/repos (6 files)

Eli Schwartz eschwartz at archlinux.org
Fri Jul 20 14:37:06 UTC 2018


    Date: Friday, July 20, 2018 @ 14:37:05
  Author: eschwartz
Revision: 362615

archrelease: copy trunk to community-staging-any

Added:
  python-celery/repos/community-staging-any/
  python-celery/repos/community-staging-any/PKGBUILD
    (from rev 362614, python-celery/trunk/PKGBUILD)
  python-celery/repos/community-staging-any/celery.tmpfiles.d
    (from rev 362614, python-celery/trunk/celery.tmpfiles.d)
  python-celery/repos/community-staging-any/celery2.tmpfiles.d
    (from rev 362614, python-celery/trunk/celery2.tmpfiles.d)
  python-celery/repos/community-staging-any/celery2 at .service
    (from rev 362614, python-celery/trunk/celery2 at .service)
  python-celery/repos/community-staging-any/celery at .service
    (from rev 362614, python-celery/trunk/celery at .service)

--------------------+
 PKGBUILD           |  108 +++++++++++++++++++++++++++++++++++++++++++++++++++
 celery.tmpfiles.d  |    2 
 celery2.tmpfiles.d |    2 
 celery2 at .service   |   15 +++++++
 celery at .service    |   15 +++++++
 5 files changed, 142 insertions(+)

Copied: python-celery/repos/community-staging-any/PKGBUILD (from rev 362614, python-celery/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2018-07-20 14:37:05 UTC (rev 362615)
@@ -0,0 +1,108 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Marcin Kolenda <marcinkolenda419 at gmail.com>
+# Contributor: Valentin Haloiu <vially.ichb+aur at gmail.com>
+# Contributor: Lukas Linhart <bugs at almad.net>
+# Contributor: Marco Elver <marco.elver AT gmail.com>
+# Contributor: apkawa <apkawa at gmail.com>
+
+pkgbase=python-celery
+pkgname=('python-celery' 'python2-celery')
+pkgver=4.2.1
+pkgrel=2
+pkgdesc='Distributed Asynchronous Task Queue'
+arch=('any')
+url='http://celeryproject.org/'
+license=('BSD')
+makedepends=('python-setuptools' 'python2-setuptools' 'python-kombu' 'python2-kombu'
+             'python-billiard' 'python2-billiard' 'python-pytz' 'python2-pytz')
+checkdepends=('python-pytest32' 'python2-pytest32' 'python-pytest-runner' 'python2-pytest-runner'
+              'python-case' 'python2-case' 'python-pyopenssl' 'python2-pyopenssl' 'python-gevent'
+              'python2-gevent' 'python2-librabbitmq' 'python-pymongo' 'python2-pymongo'
+              'python-msgpack' 'python2-msgpack' 'python-pyro' 'python2-pyro' 'python-redis'
+              'python2-redis' 'python-sqlalchemy' 'python2-sqlalchemy' 'python-boto' 'python2-boto'
+              'python-yaml' 'python2-yaml' 'python-pyzmq' 'python2-pyzmq' 'python-eventlet'
+              'python2-eventlet')
+source=("https://pypi.io/packages/source/c/celery/celery-$pkgver.tar.gz"
+        "https://github.com/celery/celery/commit/e7002769211f7340f38df80b3112706a8e07cafb.patch"
+        "https://github.com/celery/celery/commit/1c3a15938d0b9dde674d4666689d6a6c733d64e4.patch"
+        celery at .service celery2 at .service
+        celery.tmpfiles.d celery2.tmpfiles.d)
+options=('!emptydirs')
+sha512sums=('474733200e0f6aadbfab5deeb43ee563618687792d43219ebc81a53084ad491cafa410d6bb56153c3d14c76d358ce119f0055ee9b6c31e6becfe8ddf2d2178ad'
+            '98022437eb204e28ccf2c75efb4de5d38e8750ee45024955a49fa371d60aa800174820f58d7b8efd9c5e987b74cece5e75c39e0d9b63046f2ffdd210c282267b'
+            '470bbd68cbc31a48cedac4e09a45d0f414bd765450e65697d443f0e4ace8eb141735b7a4bd5d23e912d1f9d0014770bc8196bef5625b54162c7ad0df4cb7263a'
+            '3c6c9dbdacca2de12d49c03526b34797fd867c14d04115af0d1fda64d2848a5d3f64ceb6d284be319a81d932dc86e69c157b6f5f859f2fa213fc2f43a6052c65'
+            '1227803e56d5ea7879e097609b8f85633d6c0af4fa3607b98b4f30ffad093b0f3c3e7c54d965f44e954b6d9642a08e767836a9b837e225772d61dffa2042577c'
+            '67279b75c3b44d065811c9c90aee006296164000912d5bb97c74956b26ee4ad4f0847e846052a896d379848b869c849300367e676d3f689cf29e3a0c7ae5310b'
+            'ffeb86b07440de7943343d5a9348980a45d414f42dd29fd78f70e3680600e5dfb6a3a48748746e3af00f42aad9ba1cd8efeb8b2e81e86fb6febde16429b51399')
+
+prepare() {
+  # python 3.7 compat
+  patch -p1 -d celery-$pkgver < e7002769211f7340f38df80b3112706a8e07cafb.patch
+  patch -p1 -d celery-$pkgver < 1c3a15938d0b9dde674d4666689d6a6c733d64e4.patch
+  cp -a celery-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/celery-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/celery-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/celery-$pkgver
+  # Project does not officially support python 3.7, and does not wish us to
+  # open bugreports for python 3.7 issues. Backport all known python 3.7 fixes
+  # and hope for the best. https://github.com/celery/celery/issues/4913
+  python setup.py pytest || warning "tests fail on python 3.7: https://github.com/celery/celery/issues/4913"
+
+  cd "$srcdir"/celery-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-celery() {
+  depends=('python-kombu' 'python-billiard' 'python-pytz')
+  optdepends=('python-pyopenssl: for celery.security'
+              'python-pymongo: for celery.backends.mongodb'
+              'python-msgpack: for using the msgpack serializer'
+              'python-pyro: for using Pyro4 message transport'
+              'python-redis: for celery.backends.redis'
+              'python-sqlalchemy: for celery.backends.database'
+              'python-boto: for SQS transport'
+              'python-yaml: for using the yaml serializer'
+              'python-pyzmq: for using ZeroMQ transport')
+
+  cd "$srcdir"/celery-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  install -Dm644 "$srcdir"/celery at .service "$pkgdir"/usr/lib/systemd/system/celery at .service
+  install -Dm644 "$srcdir"/celery.tmpfiles.d "$pkgdir"/usr/lib/tmpfiles.d/celery.conf
+}
+
+package_python2-celery() {
+  depends=('python2-kombu' 'python2-billiard' 'python2-pytz')
+  optdepends=('python2-pyopenssl: for celery.security'
+              'python2-gevent: for celery.concurrency.gevent'
+              'python2-librabbitmq: optimized client for RabbitMQ'
+              'python2-pymongo: for celery.backends.mongodb'
+              'python2-msgpack: for using the msgpack serializer'
+              'python2-pyro: for using Pyro4 message transport'
+              'python2-redis: for celery.backends.redis'
+              'python2-sqlalchemy: for celery.backends.database'
+              'python2-boto: for SQS transport'
+              'python2-yaml: for using the yaml serializer'
+              'python2-pyzmq: for using ZeroMQ transport')
+
+  cd "$srcdir"/celery-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  install -Dm644 "$srcdir"/celery2 at .service "$pkgdir"/usr/lib/systemd/system/celery2 at .service
+  install -Dm644 "$srcdir"/celery2.tmpfiles.d "$pkgdir"/usr/lib/tmpfiles.d/celery2.conf
+
+  for _exe in "$pkgdir"/usr/bin/*; do
+    mv "$_exe"{,2}
+  done
+}

Copied: python-celery/repos/community-staging-any/celery.tmpfiles.d (from rev 362614, python-celery/trunk/celery.tmpfiles.d)
===================================================================
--- community-staging-any/celery.tmpfiles.d	                        (rev 0)
+++ community-staging-any/celery.tmpfiles.d	2018-07-20 14:37:05 UTC (rev 362615)
@@ -0,0 +1,2 @@
+d /run/celery 0755 - - - -
+d /var/log/celery 0755 - - - -

Copied: python-celery/repos/community-staging-any/celery2.tmpfiles.d (from rev 362614, python-celery/trunk/celery2.tmpfiles.d)
===================================================================
--- community-staging-any/celery2.tmpfiles.d	                        (rev 0)
+++ community-staging-any/celery2.tmpfiles.d	2018-07-20 14:37:05 UTC (rev 362615)
@@ -0,0 +1,2 @@
+d /run/celery2 0755 - - - -
+d /var/log/celery2 0755 - - - -

Copied: python-celery/repos/community-staging-any/celery2 at .service (from rev 362614, python-celery/trunk/celery2 at .service)
===================================================================
--- community-staging-any/celery2 at .service	                        (rev 0)
+++ community-staging-any/celery2 at .service	2018-07-20 14:37:05 UTC (rev 362615)
@@ -0,0 +1,15 @@
+[Unit]
+Description=Celery Nodes Daemon
+After=network.target
+
+[Service]
+Type=oneshot
+EnvironmentFile=/etc/celery/%I.conf
+ExecStart=/usr/bin/celery2 multi start $CELERYD_NODES --pidfile=/run/celery2/%n.pid --logfile=/var/log/celery2/%n.log --loglevel="INFO" $CELERYD_OPTS
+ExecStop=/usr/bin/celery2 multi stopwait $CELERYD_NODES --pidfile=/run/celery2/%n.pid
+ExecReload=/usr/bin/celery2 multi restart $CELERYD_NODES --pidfile=/run/celery2/%n.pid --logfile=/var/log/celery2/%n.log --loglevel="INFO" $CELERYD_OPTS
+KillMode=control-group
+RemainAfterExit=yes
+
+[Install]
+WantedBy=multi-user.target

Copied: python-celery/repos/community-staging-any/celery at .service (from rev 362614, python-celery/trunk/celery at .service)
===================================================================
--- community-staging-any/celery at .service	                        (rev 0)
+++ community-staging-any/celery at .service	2018-07-20 14:37:05 UTC (rev 362615)
@@ -0,0 +1,15 @@
+[Unit]
+Description=Celery Nodes Daemon
+After=network.target
+
+[Service]
+Type=oneshot
+EnvironmentFile=/etc/celery/%I.conf
+ExecStart=/usr/bin/celery multi start $CELERYD_NODES --pidfile=/run/celery/%n.pid --logfile=/var/log/celery/%n.log --loglevel="INFO" $CELERYD_OPTS
+ExecStop=/usr/bin/celery multi stopwait $CELERYD_NODES --pidfile=/run/celery/%n.pid
+ExecReload=/usr/bin/celery multi restart $CELERYD_NODES --pidfile=/run/celery/%n.pid --logfile=/var/log/celery/%n.log --loglevel="INFO" $CELERYD_OPTS
+KillMode=control-group
+RemainAfterExit=yes
+
+[Install]
+WantedBy=multi-user.target



More information about the arch-commits mailing list