[arch-commits] Commit in gwenview/repos (2 files)

[Antonio Rojas]

    Date: Friday, July 20, 2018 @ 22:38:29
  Author: arojas
Revision: 329263

archrelease: copy kde-unstable to kde-unstable-x86_64

Added:
  gwenview/repos/kde-unstable-x86_64/
  gwenview/repos/kde-unstable-x86_64/PKGBUILD
    (from rev 329262, gwenview/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: gwenview/repos/kde-unstable-x86_64/PKGBUILD (from rev 329262, gwenview/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ kde-unstable-x86_64/PKGBUILD	2018-07-20 22:38:29 UTC (rev 329263)
@@ -0,0 +1,43 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=gwenview
+pkgver=18.07.80
+pkgrel=1
+pkgdesc="A fast and easy to use image viewer"
+url='https://kde.org/applications/graphics/gwenview/'
+arch=(x86_64)
+license=(GPL LGPL FDL)
+groups=(kde-applications kdegraphics)
+depends=(kactivities baloo libkipi libkdcraw kparts kitemmodels cfitsio)
+optdepends=('qt5-imageformats: support for tiff, webp, and more image formats'
+            'kimageformats: support for dds, xcf, exr, psd, and more image formats'
+            'kipi-plugins: export to various online services'
+            'kamera: import pictures from gphoto2 cameras')
+makedepends=(extra-cmake-modules kdoctools)
+source=("https://download.kde.org/unstable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('9be5549eb7198c56640766c383a82988785427aa89f8e55894fb1dd1d1a1d20f'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DGWENVIEW_SEMANTICINFO_BACKEND="Baloo" \
+    -DBUILD_TESTING=OFF
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+}