[arch-commits] Commit in kde-dev-scripts/repos (2 files)

[Antonio Rojas]

    Date: Friday, July 20, 2018 @ 22:50:27
  Author: arojas
Revision: 329318

archrelease: copy kde-unstable to kde-unstable-any

Added:
  kde-dev-scripts/repos/kde-unstable-any/
  kde-dev-scripts/repos/kde-unstable-any/PKGBUILD
    (from rev 329317, kde-dev-scripts/kde-unstable/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: kde-dev-scripts/repos/kde-unstable-any/PKGBUILD (from rev 329317, kde-dev-scripts/kde-unstable/PKGBUILD)
===================================================================
--- kde-unstable-any/PKGBUILD	                        (rev 0)
+++ kde-unstable-any/PKGBUILD	2018-07-20 22:50:27 UTC (rev 329318)
@@ -0,0 +1,48 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgname=kde-dev-scripts
+pkgver=18.07.80
+pkgrel=1
+pkgdesc='Scripts and setting files useful during development of KDE software'
+url='https://www.kde.org/applications/development/'
+arch=(any)
+license=(GPL LGPL FDL)
+groups=(kde-applications kdesdk)
+makedepends=(extra-cmake-modules kdoctools kdelibs4support)
+replaces=(kdesdk-dev-scripts)
+conflicts=(kdesdk-dev-scripts)
+source=("https://download.kde.org/unstable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
+sha256sums=('93d1b5c93a1a0f6393f40976719817259f26567a88711f16a381e1f6d2698247'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck at kde.org>
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../$pkgname-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr
+  make
+}
+
+package() {
+  cd build
+  make DESTDIR="$pkgdir" install
+
+  # Fix python 2 path
+  sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|' \
+    "$pkgdir"/usr/bin/{zonetab2pot.py,kde-systemsettings-tree.py,reviewboard-am}
+  sed -i 's|#! /usr/bin/env python|#!/usr/bin/env python2|' \
+    "$pkgdir"/usr/bin/{kdelnk2desktop.py,kde_generate_export_header}
+
+# Install additional files
+  cd "$srcdir"/$pkgname-$pkgver
+  mkdir -p "$pkgdir"/usr/share/kde-dev-scripts
+  cp -r kde-devel-* gdb "$pkgdir"/usr/share/kde-dev-scripts
+}