[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, July 22, 2018 @ 06:06:17
  Author: felixonmars
Revision: 362741

addpkg: python-zeep 3.0.0-1

Added:
  python-zeep/
  python-zeep/repos/
  python-zeep/trunk/
  python-zeep/trunk/PKGBUILD

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Added: python-zeep/trunk/PKGBUILD
===================================================================
--- python-zeep/trunk/PKGBUILD	                        (rev 0)
+++ python-zeep/trunk/PKGBUILD	2018-07-22 06:06:17 UTC (rev 362741)
@@ -0,0 +1,37 @@
+# $Id$
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=python-zeep
+pkgver=3.0.0
+pkgrel=1
+pkgdesc="A fast and modern Python SOAP client"
+arch=('any')
+license=('MIT')
+url="http://docs.python-zeep.org"
+depends=('python-appdirs' 'python-cached-property' 'python-defusedxml' 'python-isodate'
+         'python-lxml' 'python-requests' 'python-requests-toolbelt' 'python-six' 'python-pytz')
+checkdepends=('python-pytest-runner' 'python-freezegun' 'python-mock' 'python-pretend'
+              'python-pytest-cov' 'python-requests-mock' 'python-pytest-tornado'
+              'python-aioresponses' 'python-xmlsec')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/mvantellingen/python-zeep/archive/$pkgver.tar.gz")
+sha512sums=('02b8b16a6375181697b376a7951477f0e62adc520961124f90ff61300d3ac71ccdcb298a9a0692f95f11819c12e6eb4b481bf51f69e131f59fd52e33170adcac')
+
+prepare() {
+  sed -i -e 's/==/>=/' -e '/flake8/d' -e '/isort/d' python-zeep-$pkgver/setup.py
+}
+
+build() {
+  cd python-zeep-$pkgver
+  python setup.py build
+} 
+
+check() {
+  cd python-zeep-$pkgver
+  python setup.py pytest || warning "https://github.com/mvantellingen/python-zeep/issues/724"
+}
+
+package() {
+  cd python-zeep-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}


Property changes on: python-zeep/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property